Merge pull request #10 from soblin/feature/cmake-installer

Feature/cmake installer

Author: soblin

CMakeLists.txt

@@ -1,32 +1,37 @@
-project(matplotlibcpp17)
 cmake_minimum_required(VERSION 3.12)
 
-find_package(Python3 COMPONENTS Interpreter Development NumPy)
+project(
+  "matplotlibcpp17"
+  VERSION 0.0.0
+  DESCRIPTION "A C++ header-only plotting library based on pybind11 and matplotlib, featuring more flexibility than matplotlibcpp"
+  HOMEPAGE_URL "https://soblin.github.io/matplotlibcpp17/"
+  )
+
+find_package(Python3 COMPONENTS Interpreter Development REQUIRED)
 find_package(pybind11 REQUIRED)
 
-if(NOT DEFINED ADD_DEMO)
-  set(ADD_DEMO ON)
-endif()
+set(matplotlibcpp17_INCLUDE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include")
 
+# gallery
 if(NOT DEFINED USE_GUI)
-  set(USE_GUI 0)
+  set(USE_GUI 1)
+endif()
+if(NOT DEFINED ADD_DEMO)
+  set(ADD_DEMO 1)
 endif()
-
-set(matplotlibcpp17_INCLUDE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include")
 
 function(add_demo name path)
   add_executable(${name} ${path})
   target_include_directories(${name} PUBLIC
     ${Python3_INCLUDE_DIRS}
-    ${Python3_NumPy_INCLUDE_DIRS}
-    ${pybind11_INCLUDE_DIR} 
     ${matplotlibcpp17_INCLUDE_DIRS}
     ${xtensor_INCLUDE_DIRS}
   )
   target_link_libraries(${name} ${Python3_LIBRARIES} pybind11::embed)
 endfunction()
 
 if(${ADD_DEMO})
+  find_package(Python3 COMPONENTS NumPy REQUIRED)
   find_package(xtensor REQUIRED)
   set(CMAKE_CXX_STANDARD 17)
   set(CMAKE_CXX_FLAGS "-Wall -g -DUSE_GUI=${USE_GUI}")
@@ -39,10 +44,67 @@ if(${ADD_DEMO})
   add_subdirectory(gallery/mplot3d)
 endif()
 
+
+# test
+enable_testing()
 if(NOT DEFINED DO_TEST)
   set(DO_TEST ON)
 endif()
-
 if(${DO_TEST})
   add_subdirectory(tests)
 endif()
+
+
+# install
+## https://dominikberner.ch/cmake-interface-lib/
+include(GNUInstallDirs)
+add_library(${PROJECT_NAME} INTERFACE)
+target_include_directories(${PROJECT_NAME}
+  INTERFACE
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  )
+target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_17)
+install(TARGETS ${PROJECT_NAME}
+  EXPORT ${PROJECT_NAME}_Targets
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  )
+include(CMakePackageConfigHelpers)
+write_basic_package_version_file("${PROJECT_NAME}ConfigVersion.cmake"
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMajorVersion
+  )
+configure_package_config_file(
+  "${PROJECT_SOURCE_DIR}/cmake/${PROJECT_NAME}Config.cmake.in"
+  "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
+  INSTALL_DESTINATION
+  ${CMAKE_INSTALL_DATAROOTDIR}/cmake/${PROJECT_NAME}
+  )
+install(EXPORT ${PROJECT_NAME}_Targets
+  FILE ${PROJECT_NAME}Targets.cmake
+  NAMESPACE ${PROJECT_NAME}::
+  DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/cmake/${PROJECT_NAME}
+  )
+install(FILES
+  "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
+  "${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
+  DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/cmake/${PROJECT_NAME}
+  )
+install(DIRECTORY ${PROJECT_SOURCE_DIR}/include/${PROJECT_NAME}
+  DESTINATION include
+  )
+
+# uninstall target
+## actually it's just `xargs rm < install_manifest.txt`
+## https://gitlab.kitware.com/cmake/community/-/wikis/FAQ#can-i-do-make-uninstall-with-cmake
+if(NOT TARGET uninstall)
+  configure_file(
+    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/uninstall.cmake.in"
+    "${CMAKE_CURRENT_BINARY_DIR}/uninstall.cmake"
+    IMMEDIATE @ONLY
+    )
+  add_custom_target(uninstall
+    COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/uninstall.cmake
+    )
+endif()

README.md

@@ -11,14 +11,25 @@ It is supposed to provide the user with almost full access to matplotlib feature
 ## Dependencies
 
 - [pybind11](https://github.com/pybind/pybind11) >= 2.4.3
-  - `sudo apt install pybind11-dev`
+  - `sudo apt install pybind11-dev` (on Ubuntu20.04)
+  - or manual install
 - compatible with [matplotlib](https://matplotlib.org/stable/index.html) == 3.5.1
 - numpy for `mplot3d`
-- [xtensor](https://github.com/xtensor-stack/xtensor) == 0.24.0 (+ [xtl](https://github.com/xtensor-stack/xtl), for `gallery` demos)
+- ([xtensor](https://github.com/xtensor-stack/xtensor) == 0.24.0 + [xtl](https://github.com/xtensor-stack/xtl), only for `gallery` demos)
 
-## Usage
+## Installation
 
-Just add include path to `include` directory of this project.
+```bash
+$ mdkir build; cd build;
+$ cmake .. -DADD_DEMO=0 (-DCMAKE_INSTALL_PREFIX=<custom path>)
+$ make -j
+$ make install
+$ (make uninstall)
+```
+
+For using matplotlibcpp17 from CMakeLists.txt, see [hello_world](https://github.com/soblin/matplotlibcpp17/tree/master/hello_world) example.
+
+Or you could just add include path to `include` directory and compile your codes as descibed in [minimal example](#minimal-example).
 
 ## Syntax
 
@@ -31,7 +42,7 @@ The user will need to capsulate *arguments* in `Args(arg1, arg2, ...) == pybind1
 ### minimal example
 
 ```cpp
-g++ hello_world.cpp -std=c++17 -I./include -I/usr/include/python3.x -I<path to pybind11> -lpython3.x
+g++ ./hello_world/hello_world.cpp -std=c++17 -I./include -I/usr/include/python3.x -I<path to pybind11> -lpython3.x
 ./a.out
 ```
 
@@ -148,13 +159,17 @@ From [gallery/artist_animation/random_walk.cpp](https://github.com/soblin/matplo
 
 ### build
 
+If you do not need to build the demos, use `-DADD_DEMO=0` (by default it is `1`).
+
 ```bash
-mkdir build; cd build; cmake .. ; make -j
+$ mkdir build; cd build
+$ cmake .. -DADD_DEMO={0, 1} -DUSE_GUI={0, 1}
+$ make -j
 ```
 
-If you want to see the demo with `plt.show()`, add `-DUSE_GUI=1` (by default it is `0`). Otherwise the executables will `plt.savefig()` to `gallery/images` directory.
+If you do not need to see the demo with `plt.show()`, use `-DUSE_GUI=0` (by default it is `1`). Otherwise the executables will `plt.savefig()` to `gallery/images` directory.
 
-`make <gallery directory name>` runs all executables under that directory.
+`make <gallery directory name>` runs all the executables under that directory.
 
 ```bash
 make lines_bars_and_markers

cmake/matplotlibcpp17Config.cmake.in

@@ -0,0 +1,4 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME@Targets.cmake")
+check_required_components("@PROJECT_NAME@")

cmake/uninstall.cmake.in

@@ -0,0 +1,21 @@
+if(NOT EXISTS "@CMAKE_BINARY_DIR@/install_manifest.txt")
+  message(FATAL_ERROR "Cannot find install manifest: @CMAKE_BINARY_DIR@/install_manifest.txt")
+endif()
+
+file(READ "@CMAKE_BINARY_DIR@/install_manifest.txt" files)
+string(REGEX REPLACE "\n" ";" files "${files}")
+foreach(file ${files})
+  message(STATUS "Uninstalling $ENV{DESTDIR}${file}")
+  if(IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
+    exec_program(
+      "@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
+      OUTPUT_VARIABLE rm_out
+      RETURN_VALUE rm_retval
+      )
+    if(NOT "${rm_retval}" STREQUAL 0)
+      message(FATAL_ERROR "Problem when removing $ENV{DESTDIR}${file}")
+    endif()
+  else(IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
+    message(STATUS "File $ENV{DESTDIR}${file} does not exist.")
+  endif()
+endforeach()

hello_world/CMakeLists.txt

@@ -0,0 +1,12 @@
+cmake_minimum_required(VERSION 3.12)
+
+# example of CMakeLists.txt with installed matplotlibcpp17
+project(matplotlibcpp17_hello_world)
+
+find_package(Python3 COMPONENTS Interpreter Development)
+find_package(pybind11 REQUIRED)
+find_package(matplotlibcpp17 REQUIRED)
+
+add_executable(hello_world hello_world.cpp)
+target_include_directories(hello_world PUBLIC ${Python3_INCLUDE_DIRS})
+target_link_libraries(hello_world ${Python3_LIBRARIES} pybind11::embed matplotlibcpp17::matplotlibcpp17)