Remove PHP_OUTPUT

build/php.m4

@@ -99,16 +99,6 @@ AC_DEFUN([PHP_SUBST_OLD],[
   AC_SUBST($1)
 ])
 
-dnl
-dnl PHP_OUTPUT(file)
-dnl
-dnl Adds "file" to the list of files generated by AC_OUTPUT. This macro can be
-dnl used several times.
-dnl
-AC_DEFUN([PHP_OUTPUT],[
-  PHP_OUTPUT_FILES="$PHP_OUTPUT_FILES $1"
-])
-
 dnl ----------------------------------------------------------------------------
 dnl Build system base macros.
 dnl ----------------------------------------------------------------------------

configure.ac

@@ -1563,86 +1563,93 @@ AC_DEFINE([HAVE_BUILD_DEFS_H], 1, [ ])
 $php_shtool mkdir -p scripts
 $php_shtool mkdir -p scripts/man1
 
-ALL_OUTPUT_FILES="main/build-defs.h \
-scripts/phpize scripts/man1/phpize.1 \
-scripts/php-config scripts/man1/php-config.1 \
-$PHP_OUTPUT_FILES"
-
 dnl Generate build files.
-AC_CONFIG_FILES([$ALL_OUTPUT_FILES])
-
-AC_CONFIG_COMMANDS_PRE([PHP_PATCH_CONFIG_HEADERS([main/php_config.h.in])])
-
-AC_CONFIG_COMMANDS([default],[
-cat <<X
-
-+--------------------------------------------------------------------+
-| License:                                                           |
-| This software is subject to the PHP License, available in this     |
-| distribution in the file LICENSE. By continuing this installation  |
-| process, you are bound by the terms of this license agreement.     |
-| If you do not agree with the terms of this license, you must abort |
-| the installation process at this point.                            |
-+--------------------------------------------------------------------+
-
-Thank you for using PHP.
+AC_CONFIG_FILES([
+  main/build-defs.h
+  scripts/man1/phpize.1
+  scripts/man1/php-config.1
+  scripts/phpize
+  scripts/php-config
+])
 
-X
+AC_CONFIG_FILES([
+  main/internal_functions.c
+],[
+  AWK="$AWK" sh $srcdir/build/genif.sh $srcdir/main/internal_functions.c.in "$EXT_STATIC" > main/internal_functions.c
 ],[
+  EXT_STATIC="$EXT_STATIC"
+  AWK="$AWK"
+])
 
-if test "\$CONFIG_FILES" = "$ALL_OUTPUT_FILES" || test "\$CONFIG_FILES" = " $ALL_OUTPUT_FILES" || test -z "\$CONFIG_FILES"; then
-  REDO_ALL=yes
-fi
+AC_CONFIG_FILES([
+  main/internal_functions_cli.c:main/internal_functions.c.in
+],[
+  AWK="$AWK" sh $srcdir/build/genif.sh $srcdir/main/internal_functions.c.in "$EXT_CLI_STATIC" > main/internal_functions_cli.c
+],[
+  EXT_CLI_STATIC="$EXT_CLI_STATIC"
+  AWK="$AWK"
+])
 
-dnl Create configuration headers.
-dnl ----------------------------------------------------------------------------
-test -d Zend || $php_shtool mkdir Zend
+AC_CONFIG_COMMANDS_PRE([PHP_PATCH_CONFIG_HEADERS([main/php_config.h.in])])
 
-cat >Zend/zend_config.h <<FEO
+AC_CONFIG_COMMANDS([default],[
+  test -d Zend || $php_shtool mkdir Zend
+  cat >Zend/zend_config.h <<FEO
 #include <../main/php_config.h>
 FEO
 
-dnl Run this only when generating all the files.
-if test -n "\$REDO_ALL"; then
-  echo "creating main/internal_functions.c"
-  AWK="$AWK" sh $srcdir/build/genif.sh $srcdir/main/internal_functions.c.in "$EXT_STATIC" > main/internal_functions.c
-
-  echo "creating main/internal_functions_cli.c"
-  AWK="$AWK" sh $srcdir/build/genif.sh $srcdir/main/internal_functions.c.in "$EXT_CLI_STATIC" > main/internal_functions_cli.c
-
-    if test "$PHP_SAPI" = "apache2handler"; then
-      if test "$APACHE_VERSION" -ge 2004001; then
-        if test -z "$APACHE_THREADED_MPM"; then
-cat <<X
+  if test "x$php_warning_apache" != "x"; then
+    cat <<X
 +--------------------------------------------------------------------+
 |                        *** WARNING ***                             |
 |                                                                    |
 | You have built PHP for Apache's current non-threaded MPM.          |
 | If you change Apache to use a threaded MPM you must reconfigure    |
 | PHP with --enable-maintainer-zts                                   |
 X
-        fi
-      fi
-    fi
+  fi
 
-  dnl Warn about Apache if oci8 extension is enabled on Linux.
-  if test "$PHP_OCI8" != "no"; then
-    if test "$PHP_SIGCHILD" != "yes"; then
-      if test "$PHP_OCI8_INSTANT_CLIENT" = "no"; then
-cat <<X
+  if test "x$php_warning_oci8" != "x"; then
+    cat <<X
 +--------------------------------------------------------------------+
 | Notice:                                                            |
 | If you encounter <defunc> processes when using a local Oracle      |
 | database, set the value BEQUEATH_DETACH=YES in Oracle Net's        |
 | sqlnet.ora file on the PHP host, or set the environment variable   |
-| BEQUEATH_DETACH to YES before starting Apache.  If the problem     |
+| BEQUEATH_DETACH to YES before starting Apache. If the problem      |
 | still occurs, then recompile PHP and specify --enable-sigchild     |
 | when configuring.                                                  |
 X
+  fi
+
+  cat <<X
++--------------------------------------------------------------------+
+| License:                                                           |
+| This software is subject to the PHP License, available in this     |
+| distribution in the file LICENSE. By continuing this installation  |
+| process, you are bound by the terms of this license agreement.     |
+| If you do not agree with the terms of this license, you must abort |
+| the installation process at this point.                            |
++--------------------------------------------------------------------+
+
+Thank you for using PHP.
+
+X
+],[
+  if test "$PHP_SAPI" = "apache2handler"; then
+    if test "$APACHE_VERSION" -ge 2004001; then
+      if test -z "$APACHE_THREADED_MPM"; then
+        php_warning_apache=1
       fi
     fi
   fi
 
-fi
+  if test "$PHP_OCI8" != "no"; then
+    if test "$PHP_SIGCHILD" != "yes"; then
+      if test "$PHP_OCI8_INSTANT_CLIENT" = "no"; then
+        php_warning_oci8=1
+      fi
+    fi
+  fi
 ])
 AC_OUTPUT

ext/phar/config.m4

@@ -23,5 +23,5 @@ if test "$PHP_PHAR" != "no"; then
 
   PHP_INSTALL_HEADERS([ext/phar], [php_phar.h])
 
-  PHP_OUTPUT(ext/phar/phar.1 ext/phar/phar.phar.1)
+  AC_CONFIG_FILES([ext/phar/phar.1 ext/phar/phar.phar.1])
 fi

sapi/cgi/config9.m4

@@ -69,7 +69,7 @@ if test "$PHP_CGI" != "no"; then
     PHP_SUBST(SAPI_CGI_PATH)
     PHP_SUBST(BUILD_CGI)
 
-    PHP_OUTPUT(sapi/cgi/php-cgi.1)
+    AC_CONFIG_FILES([sapi/cgi/php-cgi.1])
 else
   AC_MSG_RESULT(no)
 fi

sapi/cli/config.m4

@@ -54,7 +54,7 @@ if test "$PHP_CLI" != "no"; then
   PHP_SUBST(SAPI_CLI_PATH)
   PHP_SUBST(BUILD_CLI)
 
-  PHP_OUTPUT(sapi/cli/php.1)
+  AC_CONFIG_FILES([sapi/cli/php.1])
 
   PHP_INSTALL_HEADERS([sapi/cli/cli.h])
 fi

sapi/fpm/config.m4

@@ -634,7 +634,16 @@ if test "$PHP_FPM" != "no"; then
 
   PHP_ADD_BUILD_DIR(sapi/fpm/fpm)
   PHP_ADD_BUILD_DIR(sapi/fpm/fpm/events)
-  PHP_OUTPUT(sapi/fpm/php-fpm.conf sapi/fpm/www.conf sapi/fpm/init.d.php-fpm sapi/fpm/php-fpm.service sapi/fpm/php-fpm.8 sapi/fpm/status.html)
+
+  AC_CONFIG_FILES([
+    sapi/fpm/init.d.php-fpm
+    sapi/fpm/php-fpm.8
+    sapi/fpm/php-fpm.conf
+    sapi/fpm/php-fpm.service
+    sapi/fpm/status.html
+    sapi/fpm/www.conf
+  ])
+
   PHP_ADD_MAKEFILE_FRAGMENT([$abs_srcdir/sapi/fpm/Makefile.frag])
 
   SAPI_FPM_PATH=sapi/fpm/php-fpm

sapi/phpdbg/config.m4

@@ -88,7 +88,7 @@ if test "$BUILD_PHPDBG" = "" && test "$PHP_PHPDBG" != "no"; then
   PHP_SUBST(BUILD_PHPDBG)
   PHP_SUBST(BUILD_PHPDBG_SHARED)
 
-  PHP_OUTPUT(sapi/phpdbg/phpdbg.1)
+  AC_CONFIG_FILES([sapi/phpdbg/phpdbg.1])
 fi
 
 if test "$PHP_PHPDBG_WEBHELPER" != "no"; then

scripts/Makefile.frag

@@ -47,7 +47,7 @@ install-programs: $(builddir)/phpize $(builddir)/php-config
 	done
 
 $(builddir)/phpize: $(srcdir)/phpize.in $(top_builddir)/config.status
-	(CONFIG_FILES=$@ CONFIG_HEADERS= $(top_builddir)/config.status)
+	$(top_builddir)/config.status $@
 
 $(builddir)/php-config: $(srcdir)/php-config.in $(top_builddir)/config.status
-	(CONFIG_FILES=$@ CONFIG_HEADERS= $(top_builddir)/config.status)
+	$(top_builddir)/config.status $@