Add Example 16 - works better on Mbed OS

Author: PaulZC

README.md

@@ -16,7 +16,7 @@ An Arduino library for the u-blox SARA-R5 LTE-M / NB-IoT modules with secure clo
 
 v1.1 has had a thorough update and includes new features and examples. This library now supports up to 7 simultaneous TCP or UDP sockets. There are new examples to show how to play ping pong with both TCP and UDP sockets.
 
-v1.1 also supports binary data transfers correctly. There are new examples showing how you can integrate this library with the [SparkFun u-blox GNSS Arduino Library](https://github.com/sparkfun/SparkFun_u-blox_GNSS_Arduino_Library), to use the SARA-R5 to: download AssistNow Online and Offline data and push it to the GNSS; open a connection to a NTRIP Caster (such as RTK2go, Skylark or Emlid Caster) and push RTK correction data to the GNSS.
+v1.1 also supports binary data transfers correctly. There are new examples showing how you can integrate this library with the [SparkFun u-blox GNSS Arduino Library](https://github.com/sparkfun/SparkFun_u-blox_GNSS_Arduino_Library) and use the SARA-R5 to: download AssistNow Online and Offline data and push it to the GNSS; open a connection to a NTRIP Caster (such as RTK2go, Skylark or Emlid Caster) and push RTK correction data to the GNSS.
 
 You can install this library using the Arduino IDE Library Manager: search for _**SparkFun u-blox SARA-R5**_
 

examples/SARA-R5_Example16_GNSS_NTRIP_Caster__Polling/SARA-R5_Example16_GNSS_NTRIP_Caster__Polling.ino

@@ -0,0 +1,284 @@
+/*
+
+  SARA-R5 Example
+  ===============
+
+  u-blox GNSS NTRIP Caster Client - Polling
+
+  This version uses polling to check for the arrival of new RTK correction and NMEA GPGGA data.
+  It performs better on Mbed OS platforms: SparkFun Artemis; Arduino Nano
+
+  Written by: Paul Clark
+  Date: January 18th 2021
+
+  This example uses the SARA's mobile data connection to:
+    * Request RTK RTCM data from a NTRIP Caster service
+    * Push the RTCM data to an external u-blox GNSS module over I2C (not to the one built-in to the SARA-R510M8S)
+    * NMEA GPGGA data is pushed to the Caster every 10 seconds
+
+  The PDP profile is read from NVM. Please make sure you have run examples 4 & 7 previously to set up the profile.
+
+  Update secrets.h with your NTRIP Caster username and password
+
+  **************************************************************************************************
+  * Important Note:                                                                                *
+  *                                                                                                *
+  * This example pulls kBytes of correction data from the NTRIP Caster.                            *
+  * Depending on your location and service provider, the data rate may exceed the allowable        *
+  * rates for LTE-M or NB-IoT.                                                                     *
+  * Worst case, your service provider may throttle or block the connection - now or in the future. *
+  * We are looking for a long-term solution to this - almost certainly using LTE Cat 1 instead.    *
+  **************************************************************************************************
+  
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+
+  Licence: MIT
+  Please see LICENSE.md for full details
+
+*/
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+// The ESP32 core has a built in base64 library but not every platform does
+// We'll use an external lib if necessary.
+
+#if defined(ARDUINO_ARCH_ESP32) || defined(ARDUINO_ARCH_APOLLO3) || defined(ARDUINO_ARDUINO_NANO33BLE)
+#include "base64.h" //Built-in ESP32 library
+#else
+#include <Base64.h> //nfriendly library from https://github.com/adamvr/arduino-base64, will work with any platform
+#endif
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+#include <SparkFun_u-blox_SARA-R5_Arduino_Library.h> //Click here to get the library: http://librarymanager/All#SparkFun_u-blox_SARA-R5_Arduino_Library
+
+// Uncomment the next line to connect to the SARA-R5 using hardware Serial1
+#define saraSerial Serial1
+
+// Uncomment the next line to create a SoftwareSerial object to pass to the SARA-R5 library instead
+//SoftwareSerial saraSerial(8, 9);
+
+// Create a SARA_R5 object to use throughout the sketch
+// Usually we would tell the library which GPIO pin to use to control the SARA power (see below),
+// but we can start the SARA without a power pin. It just means we need to manually 
+// turn the power on if required! ;-D
+SARA_R5 mySARA;
+
+// Create a SARA_R5 object to use throughout the sketch
+// We need to tell the library what GPIO pin is connected to the SARA power pin.
+// If you're using the MicroMod Asset Tracker and the MicroMod Artemis Processor Board,
+// the pin name is G2 which is connected to pin AD34.
+// Change the pin number if required.
+//SARA_R5 mySARA(34);
+
+// Create a SARA_R5 object to use throughout the sketch
+// If you are using the LTE GNSS Breakout, and have access to the SARA's RESET_N pin, you can pass that to the library too
+// allowing it to do an emergency shutdown if required.
+// Change the pin numbers if required.
+//SARA_R5 mySARA(34, 35); // PWR_ON, RESET_N
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+// Globals
+
+volatile int socketNum = -1; // The TCP socket number. -1 indicates invalid/closed socket
+volatile bool connectionOpen = false; // Flag to indicate if the connection to the NTRIP Caster is open
+volatile unsigned long lastReceivedRTCM_ms; // Record when data last arrived - so we can time out if required
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+void setup()
+{
+  String currentOperator = "";
+
+  Serial.begin(115200); // Start the serial console
+
+  // Wait for user to press key to begin
+  Serial.println(F("SARA-R5 Example"));
+  Serial.println(F("Wait for the SARA NI LED to light up - then press any key to begin"));
+  
+  while (!Serial.available()) // Wait for the user to press a key (send any serial character)
+    ;
+  while (Serial.available()) // Empty the serial RX buffer
+    Serial.read();
+
+  //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+  // Start communication with the SARA-R5. Load and activate the Packet Switched Data profile.
+
+  //mySARA.enableDebugging(); // Uncomment this line to enable helpful debug messages on Serial
+
+  // For the MicroMod Asset Tracker, we need to invert the power pin so it pulls high instead of low
+  // Comment the next line if required
+  mySARA.invertPowerPin(true); 
+
+  // Initialize the SARA
+  if (mySARA.begin(saraSerial, 115200) )
+  {
+    Serial.println(F("SARA-R5 connected!"));
+  }
+  else
+  {
+    Serial.println(F("Unable to communicate with the SARA."));
+    Serial.println(F("Manually power-on (hold the SARA On button for 3 seconds) on and try again."));
+    while (1) ; // Loop forever on fail
+  }
+  Serial.println();
+
+  // First check to see if we're connected to an operator:
+  if (mySARA.getOperator(&currentOperator) == SARA_R5_SUCCESS)
+  {
+    Serial.print(F("Connected to: "));
+    Serial.println(currentOperator);
+  }
+  else
+  {
+    Serial.print(F("The SARA is not yet connected to an operator. Please use the previous examples to connect. Or wait and retry. Freezing..."));
+    while (1)
+      ; // Do nothing more
+  }
+
+  // Deactivate the PSD profile - in case one is already active
+  if (mySARA.performPDPaction(0, SARA_R5_PSD_ACTION_DEACTIVATE) != SARA_R5_SUCCESS)
+  {
+    Serial.println(F("Warning: performPDPaction (deactivate profile) failed. Probably because no profile was active."));
+  }
+
+  // Load the PSD profile from NVM - these were saved by a previous example
+  if (mySARA.performPDPaction(0, SARA_R5_PSD_ACTION_LOAD) != SARA_R5_SUCCESS)
+  {
+    Serial.println(F("performPDPaction (load from NVM) failed! Freezing..."));
+    while (1)
+      ; // Do nothing more
+  }
+
+  // Activate the profile
+  if (mySARA.performPDPaction(0, SARA_R5_PSD_ACTION_ACTIVATE) != SARA_R5_SUCCESS)
+  {
+    Serial.println(F("performPDPaction (activate profile) failed! Freezing..."));
+    while (1)
+      ; // Do nothing more
+  }
+
+  //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+  //Print the dynamic IP Address (for profile 0)
+  IPAddress myAddress;
+  mySARA.getNetworkAssignedIPAddress(0, &myAddress);
+  Serial.print(F("\r\nMy IP Address is: "));
+  Serial.print(myAddress[0]);
+  Serial.print(F("."));
+  Serial.print(myAddress[1]);
+  Serial.print(F("."));
+  Serial.print(myAddress[2]);
+  Serial.print(F("."));
+  Serial.println(myAddress[3]);
+
+  //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+  // Start I2C. Connect to the GNSS.
+
+  Wire.begin(); //Start I2C
+
+  // Uncomment the next line to enable the 'major' GNSS debug messages on Serial so you can see what AssistNow data is being sent
+  //myGNSS.enableDebugging(Serial, true);
+
+  if (myGNSS.begin() == false) //Connect to the Ublox module using Wire port
+  {
+    Serial.println(F("u-blox GPS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+  Serial.println(F("u-blox module connected"));
+
+  myGNSS.setI2COutput(COM_TYPE_UBX | COM_TYPE_NMEA);                                //Set the I2C port to output both NMEA and UBX messages
+  myGNSS.setPortInput(COM_PORT_I2C, COM_TYPE_UBX | COM_TYPE_NMEA | COM_TYPE_RTCM3); //Be sure RTCM3 input is enabled. UBX + RTCM3 is not a valid state.
+
+  myGNSS.setDGNSSConfiguration(SFE_UBLOX_DGNSS_MODE_FIXED); // Set the differential mode - ambiguities are fixed whenever possible
+
+  myGNSS.setNavigationFrequency(1); //Set the navigation rate to 1Hz
+
+  myGNSS.setAutoPVT(true); // Enable automatic PVT reports at the navigation frequency
+
+  // Set the Main Talker ID to "GP". The NMEA GGA messages will be GPGGA instead of GNGGA
+  myGNSS.setMainTalkerID(SFE_UBLOX_MAIN_TALKER_ID_GP);
+
+  myGNSS.enableNMEAMessage(UBX_NMEA_GGA, COM_PORT_I2C, 10); // Tell the module to output GGA every 10 seconds
+
+  //myGNSS.saveConfiguration(VAL_CFG_SUBSEC_IOPORT | VAL_CFG_SUBSEC_MSGCONF); //Optional: Save the ioPort and message settings to NVM
+
+}
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+void loop()
+{
+  enum states // Use a 'state machine' to open and close the connection
+  {
+    open_connection,
+    check_connection_and_wait_for_keypress,
+    close_connection,
+    waiting_for_keypress
+  };
+  static states state = open_connection;
+
+  //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+  switch (state)
+  {
+    case open_connection:
+      Serial.println(F("Connecting to the NTRIP caster..."));
+      if (beginClient((int *)&socketNum, (bool *)&connectionOpen)) // Try to open the connection to the caster
+      {
+        Serial.println(F("Connected to the NTRIP caster! Press any key to disconnect..."));
+        state = check_connection_and_wait_for_keypress; // Move on
+      }
+      else
+      {
+        Serial.print(F("Could not connect to the caster. Trying again in 5 seconds."));
+        for (int i = 0; i < 5; i++)
+        {
+          delay(1000);
+          Serial.print(F("."));
+        }
+        Serial.println();
+      }
+      break;
+
+    //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+    case check_connection_and_wait_for_keypress:
+      // If the connection has dropped or timed out, or if the user has pressed a key
+      if ((checkConnection((int)socketNum, (bool)connectionOpen) == false) || (keyPressed()))
+      {
+        state = close_connection; // Move on
+      }
+      delay(50);
+      break;
+    
+    //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+    case close_connection:
+      Serial.println(F("Closing the connection to the NTRIP caster..."));
+      closeConnection((int *)&socketNum, (bool *)&connectionOpen);
+      Serial.println(F("Press any key to reconnect..."));
+      state = waiting_for_keypress; // Move on
+      break;
+    
+    //=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
+
+    case waiting_for_keypress:
+      // Wait for the user to press a key
+      checkConnection((int)socketNum, (bool)connectionOpen); // 'Check' the connection - to print the latest PVT data
+      if (keyPressed())
+        state = open_connection; // Move on
+      break; 
+  }
+}
+
+//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=