address review comments for serial protocol support; add reset example sketch

Author: tve

examples/Example12_Reset/src/Example12_Reset.ino

@@ -0,0 +1,101 @@
+/*
+  Test baud rate changes on serial, factory reset, and hard reset.
+  By: Thorsten von Eicken
+  Date: January 29rd, 2019
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example shows how to configure the library and U-Blox for serial port use as well as
+  switching the module from the default 9600 baud to 38400.
+
+  Note: Long/lat are large numbers because they are * 10^7. To convert lat/long
+  to something google maps understands simply divide the numbers by 10,000,000. We 
+  do this so that we don't have to use floating point numbers.
+
+  Leave NMEA parsing behind. Now you can simply ask the module for the datums you want!
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Connect the U-Blox serial port to Serial1
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <SparkFun_Ublox_Arduino_Library.h> //http://librarymanager/All#SparkFun_Ublox_GPS
+SFE_UBLOX_GPS myGPS;
+
+int state = 0; // steps through auto-baud, reset, etc states
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("SparkFun Ublox Example");
+}
+
+void loop()
+{
+    Serial.print("===== STATE ");
+    Serial.println(state);
+    switch (state) {
+    case 0: // auto-baud connection, then switch to 38400 and save config
+        do {
+            Serial.println("GPS: trying 38400 baud");
+            Serial1.begin(38400);
+            if (myGPS.begin(Serial1)) break;
+
+            delay(100);
+            Serial.println("GPS: trying 9600 baud");
+            Serial1.begin(9600);
+            if (myGPS.begin(Serial1)) {
+                Serial.println("GPS: connected at 9600 baud, switching to 38400");
+                myGPS.setSerialRate(38400);
+                delay(100);
+            } else {
+                delay(2000); //Wait a bit before trying again to limit the Serial output flood
+            }
+        } while(1);
+        myGPS.setUART1Output(COM_TYPE_UBX); //Set the UART port to output UBX only
+        myGPS.saveConfiguration(); //Save the current settings to flash and BBR
+        Serial.println("GPS serial connected, saved config");
+        state++;
+        break;
+    case 1: // hardReset, expect to see GPS back at 38400 baud
+        Serial.println("Issuing hardReset (cold start)");
+        myGPS.hardReset();
+        delay(1000);
+        Serial1.begin(38400);
+        if (myGPS.begin(Serial1)) {
+            Serial.println("Success.");
+            state++;
+        } else {
+            Serial.println("*** GPS did not respond at 38400 baud, starting over.");
+            state = 0;
+        }
+        break;
+    case 2: // factoryReset, expect to see GPS back at 9600 baud
+        Serial.println("Issuing factoryReset");
+        myGPS.factoryReset();
+        delay(2000); // takes more than one second... a loop to resync would be best
+        Serial1.begin(9600);
+        if (myGPS.begin(Serial1)) {
+            Serial.println("Success.");
+            state++;
+        } else {
+            Serial.println("*** GPS did not come back at 9600 baud, starting over.");
+            state = 0;
+        }
+        break;
+    case 3: // print version info
+        Serial.print("GPS protocol version: ");
+        Serial.print(myGPS.getProtocolVersionHigh());
+        Serial.print('.');
+        Serial.print(myGPS.getProtocolVersionLow());
+        state = 0;
+    }
+    delay(1000);
+}

src/SparkFun_Ublox_Arduino_Library.cpp

@@ -68,14 +68,18 @@ void SFE_UBLOX_GPS::factoryReset()
     packetCfg.id = UBX_CFG_CFG;
     packetCfg.len = 13;
     packetCfg.startingSpot = 0;
-    for (int i=0; i<4; i++) {
+    for (uint8_t i=0; i<4; i++) {
         payloadCfg[0+i] = 0xff; // clear mask: copy default config to permanent config
         payloadCfg[4+i] = 0x00; // save mask: don't save current to permanent
         payloadCfg[8+i] = 0x00; // load mask: don't copy permanent config to current
     }
     payloadCfg[12] = 0xff; // all forms of permanent memory
     sendCommand(packetCfg, 0); // don't expect ACK
+    hardReset(); // cause factory default config to actually be loaded and used cleanly
+}
 
+void SFE_UBLOX_GPS::hardReset()
+{
     // Issue hard reset
     packetCfg.cls = UBX_CLASS_CFG;
     packetCfg.id = UBX_CFG_RST;
@@ -90,13 +94,13 @@ void SFE_UBLOX_GPS::factoryReset()
 
 //Changes the serial baud rate of the Ublox module, can't return success/fail 'cause ACK from modem
 //is lost due to baud rate change
-void SFE_UBLOX_GPS::setSerialRate(uint32_t baudrate, uint16_t maxWait)
+void SFE_UBLOX_GPS::setSerialRate(uint32_t baudrate, uint8_t uartPort, uint16_t maxWait)
 {
     //Get the current config values for the UART port
-    getPortSettings(COM_PORT_UART1, maxWait); //This will load the payloadCfg array with current port settings
+    getPortSettings(uartPort, maxWait); //This will load the payloadCfg array with current port settings
 #ifdef DEBUG
-    Serial.printf("Current baud rate: %d\n",
-            ((uint32_t)payloadCfg[10]<<16) | ((uint32_t)payloadCfg[9]<<8) | payloadCfg[8]);
+    debug.print("Current baud rate: ");
+    debug.println(((uint32_t)payloadCfg[10]<<16) | ((uint32_t)payloadCfg[9]<<8) | payloadCfg[8]);
 #endif
 
     packetCfg.cls = UBX_CLASS_CFG;
@@ -110,9 +114,8 @@ void SFE_UBLOX_GPS::setSerialRate(uint32_t baudrate, uint16_t maxWait)
     payloadCfg[10] = baudrate>>16;
     payloadCfg[11] = baudrate>>24;
 #ifdef DEBUG
-    Serial.printf("Next baud rate: %d=0x%x\n",
-            ((uint32_t)payloadCfg[10]<<16) | ((uint32_t)payloadCfg[9]<<8) | payloadCfg[8],
-            ((uint32_t)payloadCfg[10]<<16) | ((uint32_t)payloadCfg[9]<<8) | payloadCfg[8]);
+    debug.print("New baud rate:");
+    debug.println(((uint32_t)payloadCfg[10]<<16) | ((uint32_t)payloadCfg[9]<<8) | payloadCfg[8]);
 #endif
 
     sendCommand(packetCfg);

src/SparkFun_Ublox_Arduino_Library.h

@@ -206,10 +206,11 @@ class SFE_UBLOX_GPS
 
 	void printPacket(ubxPacket *packet); //Useful for debugging
 
-        void factoryReset(); //Send factory reset sequence (i.e. load "default" configuration)
+        void factoryReset(); //Send factory reset sequence (i.e. load "default" configuration and perform hardReset)
+        void hardReset(); //Perform a reset leading to a cold start (zero info start-up)
 
 	boolean setI2CAddress(uint8_t deviceAddress, uint16_t maxTime = 250); //Changes the I2C address of the Ublox module
-	void setSerialRate(uint32_t baudrate, uint16_t maxTime = 250); //Changes the serial baud rate of the Ublox module
+	void setSerialRate(uint32_t baudrate, uint8_t uartPort = COM_PORT_UART1, uint16_t maxTime = 250); //Changes the serial baud rate of the Ublox module, uartPort should be COM_PORT_UART1/2
 	void setNMEAOutputPort(Stream &nmeaOutputPort); //Sets the internal variable for the port to direct NMEA characters to
 
 	boolean setNavigationFrequency(uint8_t navFreq, uint16_t maxWait = 250); //Set the number of nav solutions sent per second