Add rename command

Author: amiralies

analysis/src/Cli.ml

@@ -8,6 +8,7 @@ API examples:
   ./rescript-editor-analysis.exe documentSymbol src/Foo.res
   ./rescript-editor-analysis.exe hover src/MyFile.res 10 2
   ./rescript-editor-analysis.exe references src/MyFile.res 10 2
+  ./rescript-editor-analysis.exe rename src/MyFile.res 10 2 foo
 
 Dev-time examples:
   ./rescript-editor-analysis.exe dump src/MyFile.res src/MyFile2.res
@@ -38,6 +39,10 @@ Options:
 
     ./rescript-editor-analysis.exe references src/MyFile.res 10 2
 
+  rename: rename all appearances of item in MyFile.res at line 10 column 2 with foo:
+
+    ./rescript-editor-analysis.exe rename src/MyFile.res 10 2 foo
+
   dump: for debugging, show all definitions and hovers for MyFile.res and MyFile.res:
 
     ./rescript-editor-analysis.exe dump src/Foo.res src/MyFile.res
@@ -50,8 +55,8 @@ Options:
 let main () =
   match Array.to_list Sys.argv with
   | [_; "completion"; path; line; col; currentFile] ->
-    Commands.completion ~path ~line:(int_of_string line) ~col:(int_of_string col)
-      ~currentFile
+    Commands.completion ~path ~line:(int_of_string line)
+      ~col:(int_of_string col) ~currentFile
   | [_; "definition"; path; line; col] ->
     Commands.definition ~path ~line:(int_of_string line)
       ~col:(int_of_string col)
@@ -62,6 +67,9 @@ let main () =
   | [_; "references"; path; line; col] ->
     Commands.references ~path ~line:(int_of_string line)
       ~col:(int_of_string col)
+  | [_; "rename"; path; line; col; newName] ->
+    Commands.rename ~path ~line:(int_of_string line) ~col:(int_of_string col)
+      ~newName
   | [_; "test"; path] -> Commands.test ~path
   | args when List.mem "-h" args || List.mem "--help" args -> prerr_endline help
   | _ ->

analysis/src/Commands.ml

@@ -176,6 +176,78 @@ let documentSymbol ~path =
     in
     print_endline ("[\n" ^ (allSymbols |> String.concat ",\n") ^ "\n]")
 
+let rename ~path ~line ~col ~newName =
+  let uri = Uri2.fromPath path in
+  let result =
+    match ProcessCmt.getFullFromCmt ~uri with
+    | None -> Protocol.null
+    | Some full -> (
+      let pos = Utils.protocolLineColToCmtLoc ~line ~col in
+      match References.locItemForPos ~full pos with
+      | None -> Protocol.null
+      | Some locItem ->
+        let allReferences = References.allReferencesForLocItem ~full locItem in
+        let referencesToToplevelModules, referencesToItems =
+          allReferences
+          |> List.fold_left
+               (fun acc (uri2, references) ->
+                 (references |> List.map (fun loc -> (uri2, loc))) @ acc)
+               []
+          |> List.partition (fun (_, loc) -> Utils.isTopLoc loc)
+        in
+        let fileRenames =
+          referencesToToplevelModules
+          |> List.map (fun (uri, _) ->
+                 let path = Uri2.toPath uri in
+                 let dir = Filename.dirname path in
+                 let ext = Filename.extension path in
+                 let sep = Filename.dir_sep in
+                 let newPath = dir ^ sep ^ newName ^ ext in
+                 let newUri = Uri2.fromPath newPath in
+                 Protocol.
+                   {
+                     kind = `rename;
+                     oldUri = uri |> Uri2.toString;
+                     newUri = newUri |> Uri2.toString;
+                   })
+        in
+        let textDocumentEdits =
+          let module StringMap = Misc.StringMap in
+          let textEditsByUri =
+            referencesToItems
+            |> List.map (fun (uri, loc) -> (Uri2.toString uri, loc))
+            |> List.fold_left
+                 (fun acc (uri, loc) ->
+                   let textEdit =
+                     Protocol.
+                       {range = Utils.cmtLocToRange loc; newText = newName}
+                   in
+                   match StringMap.find_opt uri acc with
+                   | None -> StringMap.add uri [textEdit] acc
+                   | Some prevEdits ->
+                     StringMap.add uri (textEdit :: prevEdits) acc)
+                 StringMap.empty
+          in
+          StringMap.fold
+            (fun uri edits acc ->
+              let textDocumentEdit =
+                Protocol.{textDocument = {uri; version = None}; edits}
+              in
+              textDocumentEdit :: acc)
+            textEditsByUri []
+        in
+        let fileRenamesString =
+          fileRenames |> List.map Protocol.stringifyRenameFile
+        in
+        let textDocumentEditsString =
+          textDocumentEdits |> List.map Protocol.stringifyTextDocumentEdit
+        in
+        "[\n"
+        ^ (fileRenamesString @ textDocumentEditsString |> String.concat ",\n")
+        ^ "\n]")
+  in
+  print_endline result
+
 let test ~path =
   Uri2.stripPath := true;
   match Files.readFile path with

analysis/src/Protocol.ml

@@ -18,6 +18,20 @@ type location = {uri : string; range : range}
 
 type documentSymbolItem = {name : string; kind : int; location : location}
 
+type renameFile = {kind : [`rename]; oldUri : string; newUri : string}
+
+type textEdit = {range : range; newText : string}
+
+type optionalVersionedTextDocumentIdentifier = {
+  version : int option;
+  uri : string;
+}
+
+type textDocumentEdit = {
+  textDocument : optionalVersionedTextDocumentIdentifier;
+  edits : textEdit list;
+}
+
 let null = "null"
 
 let array l = "[" ^ String.concat ", " l ^ "]"
@@ -52,7 +66,7 @@ let stringifyCompletionItem c =
 let stringifyHover h =
   Printf.sprintf {|{"contents": "%s"}|} (Json.escape h.contents)
 
-let stringifyLocation h =
+let stringifyLocation (h : location) =
   Printf.sprintf {|{"uri": "%s", "range": %s}|} (Json.escape h.uri)
     (stringifyRange h.range)
 
@@ -65,3 +79,34 @@ let stringifyDocumentSymbolItem i =
 }|}
     (Json.escape i.name) i.kind
     (stringifyLocation i.location)
+
+let stringifyRenameFile rf =
+  Printf.sprintf {|{
+  "kind": "rename",
+  "oldUri": "%s",
+  "newUri": "%s"
+}|}
+    (Json.escape rf.oldUri) (Json.escape rf.newUri)
+
+let stringifyTextEdit te =
+  Printf.sprintf {|{
+  "range": %s,
+  "newText": "%s"
+  }|}
+    (stringifyRange te.range) (Json.escape te.newText)
+
+let stringifyoptionalVersionedTextDocumentIdentifier td =
+  Printf.sprintf {|{
+  "version": %s,
+  "uri": "%s"
+  }|}
+    (match td.version with None -> null | Some v -> string_of_int v)
+    (Json.escape td.uri)
+
+let stringifyTextDocumentEdit tde =
+  Printf.sprintf {|{
+  "textDocument": %s,
+  "edits": %s
+  }|}
+    (stringifyoptionalVersionedTextDocumentIdentifier tde.textDocument)
+    (tde.edits |> List.map stringifyTextEdit |> array)

analysis/src/Utils.ml

@@ -7,6 +7,12 @@ let topLoc fname =
     loc_ghost = false;
   }
 
+let isTopLoc (loc : Warnings.loc) =
+  let isTopPos (pos : Lexing.position) =
+    pos.pos_lnum = 1 && pos.pos_bol = 0 && pos.pos_cnum = 0
+  in
+  isTopPos loc.loc_start && isTopPos loc.loc_end && loc.loc_ghost = false
+
 (**
  * `startsWith(string, prefix)`
  * true if the string starts with the prefix