Fix GH-9653: does not inconditionally support copy_file_range on older kernels.

As mentioned in its manpage, it had been reworked in the 5.3 line to support cross filesystem interactions.

Author: devnexen

configure.ac

@@ -364,7 +364,6 @@ PHP_CHECK_FUNC(socketpair, socket, network)
 PHP_CHECK_FUNC(htonl, socket, network)
 PHP_CHECK_FUNC(gethostname, nsl, network)
 PHP_CHECK_FUNC(gethostbyaddr, nsl, network)
-PHP_CHECK_FUNC(copy_file_range)
 PHP_CHECK_FUNC(dlopen, dl, root)
 PHP_CHECK_FUNC(dlsym, dl, root)
 if test "$ac_cv_func_dlopen" = "yes"; then
@@ -691,6 +690,39 @@ if test "$ac_cv_func_getaddrinfo" = yes; then
   AC_DEFINE(HAVE_GETADDRINFO,1,[Define if you have the getaddrinfo function])
 fi
 
+AC_CACHE_CHECK([for copy_file_range], ac_cv_copy_file_range,
+[AC_RUN_IFELSE([AC_LANG_SOURCE([[
+#if defined(__linux__)
+#if !defined(_GNU_SOURCE)
+#define _GNU_SOURCE
+#endif
+#include <linux/version.h>
+#elif defined(__FreeBSD__)
+// TODO checks kernel version once this syscall is fixed on FreeBSD
+#include <sys/param.h>
+#include <sys/types.h>
+#endif
+#include <unistd.h>
+
+int main(void) {
+(void)copy_file_range(-1, 0, -1, 0, 0, 0);
+#if defined(__linux__)
+#if LINUX_VERSION_CODE < KERNEL_VERSION(5,3,0)
+return 1;
+#else
+return 0;
+#endif
+#else
+return 1;
+#endif
+}
+]])], [ac_cv_copy_file_range=yes], [ac_cv_copy_file_range=no])
+])
+
+if test "$ac_cv_copy_file_range" = yes; then
+  AC_DEFINE(HAVE_COPY_FILE_RANGE,1,[Define if copy_file_range support])
+fi
+
 AC_REPLACE_FUNCS(strlcat strlcpy explicit_bzero getopt)
 AC_FUNC_ALLOCA
 PHP_TIME_R_TYPE