test(collection/estimation): test collection estimation page

Fix #893

Author: mukeshk

src/main/webapp/WEB-INF/views/collection/estimation.html

@@ -67,12 +67,12 @@ <h3 class="text-center" th:text="#{t_collection_of(${ownerName})}">
 					</h3>
 
 					<!--/*/
-					<p class="text-center" th:if="${#lists.isEmpty(seriesOfCollection)}" th:text="#{t_empty_collection}">
+					<p id="empty-collection-msg" class="text-center" th:if="${#lists.isEmpty(seriesOfCollection)}" th:text="#{t_empty_collection}">
 						In this collection is no stamps
 					</p>
 					/*/-->
 
-					<table class="table table-hover" th:if="${not #lists.isEmpty(seriesOfCollection)}">
+					<table id="collection-estimation" class="table table-hover" th:if="${not #lists.isEmpty(seriesOfCollection)}">
 						<thead>
 							<tr class="active">
 								<th th:text="#{t_series}">Series</th>

src/test/robotframework/collection/estimation/logic.robot

@@ -0,0 +1,42 @@
+*** Settings ***
+Documentation   Verify collection estimation scenarios
+Library         SeleniumLibrary
+Resource        ../../auth.steps.robot
+Resource        ../../selenium.utils.robot
+Suite Setup     Before Test Suite
+Suite Teardown  Close Browser
+Force Tags      collection  estimation  logic
+
+*** Test Cases ***
+Message should be shown when a collection is empty
+	Go To                   ${SITE_URL}/collection/paid/estimation
+	Element Text Should Be  id=empty-collection-msg  In this collection is no stamps
+
+Series with its price should be taken into account
+	[Tags]                       unstable
+	Go To                        ${SITE_URL}/series/1
+	Input Text                   id=paid-price  100
+	Select From List By Value    id=paid-currency  ${expectedCurrency}
+	Submit Form                  id=add-series-form
+	Go To                        ${SITE_URL}/collection/paid/estimation
+	# TODO: use "Table Footer Should Contain" instead, when it will be fixed.
+    # See https://github.com/Hi-Fi/robotframework-seleniumlibrary-java/issues/88
+	Table Header Should Contain  collection-estimation  100.00 ${expectedCurrency}
+
+Series without price should be shown but not taken into account
+	[Tags]                       unstable
+	Go To                        ${SITE_URL}/series/2
+	Submit Form                  id=add-series-form
+	Go To                        ${SITE_URL}/collection/paid/estimation
+	# TODO: use "Table Footer Should Contain" instead, when it will be fixed.
+    # See https://github.com/Hi-Fi/robotframework-seleniumlibrary-java/issues/88
+	Table Header Should Contain  collection-estimation  100.00 ${expectedCurrency}
+
+*** Keywords ***
+Before Test Suite
+	@{currencies}=                      Create List	USD  EUR  RUB  CZK
+	${randomCurrency}=                  Evaluate  random.choice(${currencies})  modules=random  
+	Set Suite Variable                  ${expectedCurrency}  ${randomCurrency}
+	Open Browser                        ${SITE_URL}/account/auth  ${BROWSER}
+	Register Keyword To Run On Failure  Log Source
+	Log In As                           login=paid  password=test