Make coverageReport and projectCoverageReport functions

- Make the "coverageReport" and "projectCoverageReport" functions
  available to the user.
- The existing "coverageReport" and "projectCoverageReport" attributes
  have been renamed to "coverageReport'" and "projectCoverageReport'".
  They remain for convenience.
- Updated the documentation accordingly.

Author: sevanspowell

docs/tutorials/coverage.md

@@ -3,44 +3,60 @@
 haskell.nix can generate coverage information for your package or
 project using Cabal's inbuilt hpc support.
 
-## Pre-requisites
-
-It is currently required that you enable coverage for each library you
-want coverage for prior to attempting to generate a coverage report. I
-hope to fix this before merging this PR:
-
-```nix
-  haskell-nix.cabalProject ({
-    src = pkgs.haskell-nix.haskellLib.cleanGit {
-      name = "haskell-nix-project";
-      src = ./.;
-    };
-    modules = [
-      {
-        packages.package-1.components.library.doCoverage = true;
-        packages.package-2.components.library.doCoverage = true;
-      }
-    ];
-  });
-```
-
 ## Per-package
 
 ```bash
-nix-build default.nix -A $pkg.coverageReport
+nix-build default.nix -A "$pkg.coverageReport'"
 ```
 
-This will generate a coverage report for the package you requested.
+This will generate a coverage report for the package you requested. By
+default, all tests that are enabled (configured with
+`doCheck == true`) are included in the coverage report.
 
 See the [developer coverage docs](../dev/coverage.md#package-reports) for more information.
 
 ## Project-wide
 
 ```bash
-nix-build default.nix -A projectCoverageReport
+nix-build default.nix -A "projectCoverageReport'"
 ```
 
 This will generate a coverage report for all the local packages in
 your project.
 
 See the [developer coverage docs](../dev/coverage.md#project-wide-reports) for more information.
+
+## Custom
+
+haskell.nix also exposes two functions which allow you to generate
+custom coverage reports: `coverageReport` and `projectCoverageReport`.
+These are found in the haskell.nix library:
+
+```nix
+let
+  inherit (pkgs.haskell-nix) haskellLib;
+
+  project = pkgs.haskell-nix.project {
+    # 'cleanGit' cleans a source directory based on the files known by git
+    src = pkgs.haskell-nix.haskellLib.cleanGit {
+      name = "haskell-nix-project";
+      src = ./.;
+    };
+    # For `cabal.project` based projects specify the GHC version to use.
+    compiler-nix-name = "ghc884"; # Not used for `stack.yaml` based projects.
+  };
+
+  custom$pkgCoverageReport = haskellLib.coverageReport {
+    inherit (project.$pkg.identifier) name version;
+    inherit (project.$pkg.components) library tests;
+  };
+
+  customProjectCoverageReport = haskellLib.projectCoverageReport {
+    packages                = haskellLib.selectProjectPackages project;
+    coverageReportOverrides = { "${project.$pkg.identifier.name}" = custom$pkgCoverageReport; };
+  };
+in project // {
+  inherit custom$pkgCoverageReport customProjectCoverageReport;
+}
+
+```

lib/cover-project.nix

@@ -1,8 +1,12 @@
 { pkgs, stdenv, lib, haskellLib }:
 
-project:
+# List of project packages to generate a coverage report for
+{ packages
+, coverageReportOverrides ? {}
+}:
 
 let
+  getPackageCoverageReport = packageName: (coverageReportOverrides."${packageName}" or packages."${packageName}".coverageReport');
 
   # Create table rows for an project coverage index page that look something like:
   #
@@ -55,7 +59,7 @@ let
             <th>TestSuite</th>
           </tr>
 
-          ${with lib; concatStringsSep "\n" (mapAttrsToList (_ : packageTableRows) project)}
+          ${with lib; concatStringsSep "\n" (mapAttrsToList (_ : packageTableRows) packages)}
 
         </tbody>
       </table>
@@ -92,7 +96,7 @@ stdenv.mkDerivation {
 
     ${with lib; concatStringsSep "\n" (mapAttrsToList (n: package: ''
       identifier="${package.identifier.name}-${package.identifier.version}"
-      report=${package.coverageReport}
+      report=${getPackageCoverageReport n}
       tix="$report/share/hpc/tix/$identifier/$identifier.tix"
       if test -f "$tix"; then
         tixFiles+=("$tix")
@@ -102,7 +106,7 @@ stdenv.mkDerivation {
       cp -R $report/share/hpc/mix/* $out/share/hpc/mix
       cp -R $report/share/hpc/tix/* $out/share/hpc/tix
       cp -R $report/share/hpc/html/* $out/share/hpc/html
-    '') project)}
+    '') packages)}
 
     if [ ''${#tixFiles[@]} -ne 0 ]; then
       hpcSumCmd+=("''${tixFiles[@]}")

lib/cover.nix

@@ -1,19 +1,22 @@
 { stdenv, lib, haskellLib, pkgs }:
 
-{ name, version, library, tests, plan }:
+{ name
+, version
+, library
+, tests
+}:
 
 let
   buildWithCoverage = builtins.map (d: d.covered);
   runCheck = builtins.map (d: haskellLib.check d);
 
+  testsAsList       = lib.attrValues tests;
   libraryCovered    = library.covered;
-  testsWithCoverage = buildWithCoverage tests;
+  testsWithCoverage = buildWithCoverage testsAsList;
   checks            = runCheck testsWithCoverage;
 
   identifier = name + "-" + version;
 
-  getTestModulesFor = test: plan.components.tests."${test.exeName}".modules;
-
 in stdenv.mkDerivation {
   name = (identifier + "-coverage-report");
 
@@ -41,11 +44,11 @@ in stdenv.mkDerivation {
       hpcMarkupCmdBase+=("--hpcdir=$mixDir")
     done
 
-    ${lib.optionalString ((builtins.length tests) > 0) ''
+    ${lib.optionalString ((builtins.length testsAsList) > 0) ''
       # Exclude test modules from tix file
       excludedModules=('Main')
       # Exclude test modules
-      testModules="${with lib; concatStringsSep " " (foldl' (acc: test: acc ++ (getTestModulesFor test)) [] testsWithCoverage)}"
+      testModules="${with lib; concatStringsSep " " (foldl' (acc: test: acc ++ test.config.modules) [] testsWithCoverage)}"
       for module in $testModules; do
         excludedModules+=("$module")
       done

overlays/haskell.nix

@@ -480,7 +480,7 @@ final: prev: {
                   inherit (callProjectResults) index-state;
                 };
             in project // {
-                projectCoverageReport = haskellLib.projectCoverageReport (haskellLib.selectProjectPackages project.hsPkgs);
+              projectCoverageReport' = haskellLib.projectCoverageReport { packages = haskellLib.selectProjectPackages project.hsPkgs; };
             };
 
         # Take `hsPkgs` from the `rawProject` and update all the packages and
@@ -503,11 +503,10 @@ final: prev: {
                       ) package'.components;
                       inherit project;
 
-                      coverageReport = haskellLib.coverageReport {
+                      coverageReport' = haskellLib.coverageReport {
                         inherit (package.identifier) name version;
                         inherit (components) library;
-                        tests = with final.lib; attrValues (filterAttrs (_: d: d.config.doCheck) components.tests);
-                        plan = project.pkg-set.config.packages."${package.identifier.name}";
+                        tests = final.lib.filterAttrs (_: d: d.config.doCheck) components.tests;
                       };
                     }
                 ) rawProject.hsPkgs
@@ -519,7 +518,7 @@ final: prev: {
 
         cabalProject = args: let p = cabalProject' args;
             in p.hsPkgs // {
-              inherit (p) plan-nix projectCoverageReport;
+              inherit (p) plan-nix projectCoverageReport';
               # Provide `nix-shell -A shells.ghc` for users migrating from the reflex-platform.
               # But we should encourage use of `nix-shell -A shellFor`
               shells.ghc = p.hsPkgs.shellFor {};
@@ -543,12 +542,12 @@ final: prev: {
                   stack-nix = callProjectResults.projectNix;
                 };
             in project // {
-                projectCoverageReport = haskellLib.projectCoverageReport (haskellLib.selectProjectPackages project.hsPkgs);
+              projectCoverageReport' = haskellLib.projectCoverageReport { packages = haskellLib.selectProjectPackages project.hsPkgs; };
             };
 
         stackProject = args: let p = stackProject' args;
             in p.hsPkgs // {
-              inherit (p) stack-nix;
+              inherit (p) stack-nix projectCoverageReport';
               # Provide `nix-shell -A shells.ghc` for users migrating from the reflex-platform.
               # But we should encourage use of `nix-shell -A shellFor`
               shells.ghc = p.hsPkgs.shellFor {};

test/coverage/default.nix

@@ -15,8 +15,8 @@ let
     }];
   };
 
-  cabalProject = cabalProject' projectArgs;
-  stackProject = stackProject' projectArgs;
+  cabalProj = cabalProject' projectArgs;
+  stackProj = stackProject' projectArgs;
 
 in recurseIntoAttrs ({
   run = stdenv.mkDerivation {
@@ -75,12 +75,12 @@ in recurseIntoAttrs ({
       }
 
       ${concatStringsSep "\n" (map (project: ''
-        pkga_basedir="${project.hsPkgs.pkga.coverageReport}/share/hpc/"
+        pkga_basedir="${project.hsPkgs.pkga.coverageReport'}/share/hpc/"
         findFileExistsNonEmpty "$pkga_basedir/mix/pkga-0.1.0.0/" "PkgA.mix"
         dirExistsEmpty "$pkga_basedir/tix/pkga-0.1.0.0"
         dirExistsEmpty "$pkga_basedir/html/pkga-0.1.0.0"
   
-        pkgb_basedir="${project.hsPkgs.pkgb.coverageReport}/share/hpc/"
+        pkgb_basedir="${project.hsPkgs.pkgb.coverageReport'}/share/hpc/"
         testTix="$pkgb_basedir/tix/tests/tests.tix"
         libTix="$pkgb_basedir/tix/pkgb-0.1.0.0/pkgb-0.1.0.0.tix"
         fileExistsNonEmpty "$testTix"
@@ -98,7 +98,7 @@ in recurseIntoAttrs ({
           exit 1
         fi
 
-        project_basedir="${project.projectCoverageReport}/share/hpc/"
+        project_basedir="${project.projectCoverageReport'}/share/hpc/"
         fileExistsNonEmpty "$project_basedir/html/index.html"
         fileExistsNonEmpty "$project_basedir/tix/all/all.tix"
         dirExists "$project_basedir/html/pkga-0.1.0.0"
@@ -111,7 +111,7 @@ in recurseIntoAttrs ({
         dirExists "$project_basedir/tix/pkga-0.1.0.0"
         dirExists "$project_basedir/tix/pkgb-0.1.0.0"
         dirExists "$project_basedir/tix/tests"
-      '') [ cabalProject stackProject ])}
+      '') [ cabalProj stackProj ])}
 
       touch $out
     '';
@@ -120,7 +120,7 @@ in recurseIntoAttrs ({
 
     passthru = {
       # Used for debugging with nix repl
-      inherit cabalProject stackProject;
+      inherit cabalProj stackProj;
     };
   };
 })