Add query for RULE 13-2

Author: rvermeulen

c/misra/src/rules/RULE-13-2/UnsequencedSideEffects.ql

@@ -0,0 +1,59 @@
+/**
+ * @id c/misra/unsequenced-side-effects
+ * @name RULE-13-2: The value of an expression and its persistent side effects depend on its evaluation order
+ * @description The value of an expression and its persistent side effects are depending on the
+ *              evaluation order resulting in unpredictable behavior.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity error
+ * @tags external/misra/id/rule-13-2
+ *       correctness
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+import codingstandards.c.Expr
+import codingstandards.c.SideEffects
+import codingstandards.c.Ordering
+
+predicate isCandidatePair(Expr parentExpr, Expr e1, Expr e2) {
+  parentExpr.getAChild+() = e1 and
+  parentExpr.getAChild+() = e2
+}
+
+class ConstituentExprOrdering extends Ordering::Configuration {
+  ConstituentExprOrdering() { this = "ConstituentExprOrdering" }
+
+  override predicate isCandidate(Expr e1, Expr e2) {
+    // Two different expressions part of the same full expression.
+    // Compute differerence using successor relation to break the symmetry of the candidate relation.
+    isCandidatePair(_, e1, e2)
+  }
+}
+
+from
+  ConstituentExprOrdering orderingConfig, FullExpr fullExpr, VariableEffect variableEffect1,
+  VariableEffect variableEffect2
+where
+  not isExcluded(fullExpr, SideEffects3Package::unsequencedSideEffectsQuery()) and
+  // If the effect is local we can directly check if it is unsequenced.
+  // If the effect is not local (happens in a different function) we use the access as a proxy.
+  orderingConfig.isUnsequenced(variableEffect1, variableEffect2) and
+  fullExpr.getAChild+() = variableEffect1 and
+  fullExpr.getAChild+() = variableEffect2 and
+  // Both are evaluated
+  not exists(ConditionalExpr ce |
+    ce.getThen().getAChild*() = variableEffect1 and ce.getElse().getAChild*() = variableEffect2
+  ) and
+  // Break the symmetry of the ordering relation by requiring that the first expression is located before the second.
+  // This builds upon the assumption that the expressions are part of the same full expression as specified in the ordering configuration.
+  exists(int offset1, int offset2 |
+    variableEffect1.getLocation().charLoc(_, offset1, _) and
+    variableEffect2.getLocation().charLoc(_, offset2, _) and
+    offset1 < offset2
+  )
+select fullExpr, "The expression contains unsequenced $@ to $@ and $@ to $@.", variableEffect1,
+  "side effect", variableEffect1.getAnAccess(), variableEffect1.getTarget().getName(),
+  variableEffect2, "side effect", variableEffect2.getAnAccess(),
+  variableEffect2.getTarget().getName()

c/misra/test/rules/RULE-13-2/UnsequencedSideEffects.expected

@@ -0,0 +1,5 @@
+| test.c:6:12:6:18 | ... + ... | The expression contains unsequenced $@ to $@ and $@ to $@. | test.c:6:12:6:13 | l1 | side effect | test.c:6:12:6:13 | l1 | l1 | test.c:6:17:6:18 | l1 | side effect | test.c:6:17:6:18 | l1 | l1 |
+| test.c:7:12:7:18 | ... + ... | The expression contains unsequenced $@ to $@ and $@ to $@. | test.c:7:12:7:13 | l1 | side effect | test.c:7:12:7:13 | l1 | l1 | test.c:7:17:7:18 | l2 | side effect | test.c:7:17:7:18 | l2 | l2 |
+| test.c:17:3:17:21 | ... = ... | The expression contains unsequenced $@ to $@ and $@ to $@. | test.c:17:8:17:9 | l1 | side effect | test.c:17:8:17:9 | l1 | l1 | test.c:17:13:17:14 | l1 | side effect | test.c:17:13:17:14 | l1 | l1 |
+| test.c:19:3:19:5 | call to foo | The expression contains unsequenced $@ to $@ and $@ to $@. | test.c:19:7:19:8 | l1 | side effect | test.c:19:7:19:8 | l1 | l1 | test.c:19:11:19:12 | l2 | side effect | test.c:19:11:19:12 | l2 | l2 |
+| test.c:25:3:25:5 | call to foo | The expression contains unsequenced $@ to $@ and $@ to $@. | test.c:25:7:25:10 | ... ++ | side effect | test.c:25:7:25:8 | l8 | l8 | test.c:25:13:25:16 | ... ++ | side effect | test.c:25:13:25:14 | l9 | l9 |

c/misra/test/rules/RULE-13-2/UnsequencedSideEffects.qlref

@@ -0,0 +1 @@
+rules/RULE-13-2/UnsequencedSideEffects.ql

c/misra/test/rules/RULE-13-2/test.c

@@ -0,0 +1,28 @@
+void foo(int, int);
+
+void unsequenced_sideeffects() {
+  volatile int l1, l2;
+
+  int l3 = l1 + l1; // NON_COMPLIANT
+  int l4 = l1 + l2; // NON_COMPLIANT
+
+  // Store value of volatile object in temporary non-volatile object.
+  int l5 = l1;
+  // Store value of volatile object in temporary non-volatile object.
+  int l6 = l2;
+  int l7 = l5 + l6; // COMPLIANT
+
+  int l8, l9;
+  l1 = l1 & 0x80;      // COMPLIANT
+  l8 = l1 = l1 & 0x80; // NON_COMPLIANT
+
+  foo(l1, l2); // NON_COMPLIANT
+  // Store value of volatile object in temporary non-volatile object.
+  l8 = l1;
+  // Store value of volatile object in temporary non-volatile object.
+  l9 = l2;
+  foo(l8, l9);     // COMPLIANT
+  foo(l8++, l9++); // NON_COMPLIANT
+
+  int l10 = l8++, l11 = l8++; // COMPLIANT
+}