Rule 5.8: Improve performance

This rule was highlighted as performing poorly as it created an
effective cross product on declarations with the same name, which is
expensive on some databases.

The performance fix is to:
 (a) Create a predicate which represents all the conflicting identifiers
     by simply counting the number of declarations and confirming at
     least on such declaration is external.
 (b) Use this to create a result table of Declarations that conflict
     with those identifiers.
 (c) Implement a "non unique" external identifier class that provides a
     member predicate to get all the conflicting declarations.

The key point here is to prevent the optimiser from doing a join between
Declaration.getName() and Declaration.getName(). Instead, the join is
between the names of the non-unique external identifiers and the much
smaller table of declarations that conflict with at least one such
entry.

Author: lcartey

c/misra/src/rules/RULE-5-8/IdentifiersWithExternalLinkageNotUnique.ql

@@ -15,10 +15,39 @@ import cpp
 import codingstandards.c.misra
 import codingstandards.cpp.Identifiers
 
-from Declaration de, ExternalIdentifiers e
+/**
+ * Holds if the `identifierName` has conflicting declarations.
+ */
+predicate isExternalIdentifierNotUnique(string identifierName) {
+  // More than one declaration with this name
+  count(Declaration d | d.getName() = identifierName) > 1 and
+  // At least one declaration is an external identifier
+  exists(ExternalIdentifiers e | e.getName() = identifierName)
+}
+
+/**
+ * Holds if the `Declaration` `d` is conflicting with an external identifier.
+ */
+predicate isConflictingDeclaration(Declaration d, string name) {
+  isExternalIdentifierNotUnique(name) and
+  d.getName() = name
+}
+
+/**
+ * An external identifier which is not uniquely defined in the source code.
+ */
+class NotUniqueExternalIdentifier extends ExternalIdentifiers {
+  NotUniqueExternalIdentifier() { isExternalIdentifierNotUnique(getName()) }
+
+  Declaration getAConflictingDeclaration() {
+    not result = this and
+    isConflictingDeclaration(result, getName())
+  }
+}
+
+from NotUniqueExternalIdentifier e, Declaration de
 where
   not isExcluded(de, Declarations6Package::identifiersWithExternalLinkageNotUniqueQuery()) and
   not isExcluded(e, Declarations6Package::identifiersWithExternalLinkageNotUniqueQuery()) and
-  not de = e and
-  de.getName() = e.getName()
+  de = e.getAConflictingDeclaration()
 select de, "Identifier conflicts with external identifier $@", e, e.getName()