Implement Language4 package, banning obsolete language features.

Many of the cases outlined in the amendment are covered by other rules. Add
support for new cases where possible (was not possible for ID 3, storage class
specifiers not at beginning of declaration, or ID 2, which is a feature of the
implementation not determinable by static analysis), and reference existing
rules in one comprehensive test for maximal clarity that those parts of rule
1-5 are indeed supported by our existing queries.

Author: MichaelRFairhurst

c/misra/src/rules/RULE-1-5/CallToReallocWithSizeZero.ql

@@ -0,0 +1,24 @@
+/**
+ * @id c/misra/call-to-realloc-with-size-zero
+ * @name RULE-1-5: Disallowed size argument value equal to zero in call to realloc
+ * @description Invoking realloc with a size argument set to zero is implementation-defined behavior
+ *              and declared as an obsolete feature in C18.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity error
+ * @tags external/misra/id/rule-1-5
+ *       correctness
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+import semmle.code.cpp.rangeanalysis.new.RangeAnalysis
+
+from FunctionCall call, Expr arg
+where
+  not isExcluded(call, Language4Package::callToReallocWithSizeZeroQuery()) and
+  call.getTarget().hasGlobalOrStdName("realloc") and
+  arg = call.getArgument(1) and
+  upperBound(arg) = 0
+select arg, "Calling realloc with size zero results in implementation-defined behavior."

c/misra/src/rules/RULE-1-5/InvalidDefineOrUndefOfStdBoolMacro.ql

@@ -0,0 +1,31 @@
+/**
+ * @id c/misra/invalid-define-or-undef-of-std-bool-macro
+ * @name RULE-1-5: Programs may not undefine or redefine the macros bool, true, or false
+ * @description Directives that undefine and/or redefine the standard boolean macros has been
+ *              declared an obsolescent language feature since C99.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity warning
+ * @tags external/misra/id/rule-1-5
+ *       maintainability
+ *       readability
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+
+string getABoolMacroName() { result = ["true", "false", "bool"] }
+
+from PreprocessorDirective directive, string opString, string macroName
+where
+  not isExcluded(directive, Language4Package::invalidDefineOrUndefOfStdBoolMacroQuery()) and
+  macroName = getABoolMacroName() and
+  (
+    macroName = directive.(Macro).getName() and
+    opString = "define"
+    or
+    macroName = directive.(PreprocessorUndef).getName() and
+    opString = "undefine"
+  )
+select directive, "Invalid " + opString + " of boolean standard macro " + macroName

c/misra/src/rules/RULE-1-5/UseOfObsoleteMacroAtomicVarInit.ql

@@ -0,0 +1,24 @@
+/**
+ * @id c/misra/use-of-obsolete-macro-atomic-var-init
+ * @name RULE-1-5: Disallowed usage of obsolete macro ATOMIC_VAR_INIT compiled as C18
+ * @description The macro ATOMIC_VAR_INIT is has been declared an obsolescent language feature since
+ *              C18.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity recommendation
+ * @tags external/misra/id/rule-1-5
+ *       maintainability
+ *       readability
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+
+from MacroInvocation invoke, Compilation c, string flag
+where
+  not isExcluded(invoke, Language4Package::useOfObsoleteMacroAtomicVarInitQuery()) and
+  invoke.getMacroName() = "ATOMIC_VAR_INIT" and
+  flag = c.getAnArgument() and
+  flag.regexpMatch("-std=c1[78]")
+select invoke, "Usage of macro ATOMIC_VAR_INIT() is considered obsolete for c version " + flag

c/misra/test/rules/RULE-1-5/CallToReallocWithSizeZero.expected

@@ -0,0 +1 @@
+| test.c:13:14:13:14 | 0 | Calling realloc with size zero results in implementation-defined behavior. |

c/misra/test/rules/RULE-1-5/CallToReallocWithSizeZero.qlref

@@ -0,0 +1 @@
+rules/RULE-1-5/CallToReallocWithSizeZero.ql

c/misra/test/rules/RULE-1-5/FunctionTypesNotInPrototypeForm.expected

@@ -0,0 +1,2 @@
+| test.c:40:6:40:7 | f2 | Function f2 does not specify void for no parameters present. |
+| test.c:44:5:44:6 | f5 | Function f5 declares parameter in unsupported declaration list. |

c/misra/test/rules/RULE-1-5/FunctionTypesNotInPrototypeForm.qlref

@@ -0,0 +1 @@
+rules/RULE-8-2/FunctionTypesNotInPrototypeForm.ql

c/misra/test/rules/RULE-1-5/InvalidDefineOrUndefOfStdBoolMacro.expected

@@ -0,0 +1,6 @@
+| test.c:23:1:23:14 | #define true 3 | Invalid define of boolean standard macro true |
+| test.c:24:1:24:15 | #define false 3 | Invalid define of boolean standard macro false |
+| test.c:25:1:25:18 | #define bool int * | Invalid define of boolean standard macro bool |
+| test.c:26:1:26:11 | #undef true | Invalid undefine of boolean standard macro true |
+| test.c:27:1:27:12 | #undef false | Invalid undefine of boolean standard macro false |
+| test.c:28:1:28:11 | #undef bool | Invalid undefine of boolean standard macro bool |

c/misra/test/rules/RULE-1-5/InvalidDefineOrUndefOfStdBoolMacro.qlref

@@ -0,0 +1 @@
+rules/RULE-1-5/InvalidDefineOrUndefOfStdBoolMacro.ql

c/misra/test/rules/RULE-1-5/MemoryAllocDeallocFunctionsOfStdlibhUsed.expected

@@ -0,0 +1,3 @@
+| test.c:10:12:10:17 | call to malloc | Use of banned dynamic memory allocation. |
+| test.c:13:3:13:9 | call to realloc | Use of banned dynamic memory allocation. |
+| test.c:16:3:16:9 | call to realloc | Use of banned dynamic memory allocation. |

c/misra/test/rules/RULE-1-5/MemoryAllocDeallocFunctionsOfStdlibhUsed.qlref

@@ -0,0 +1 @@
+rules/RULE-21-3/MemoryAllocDeallocFunctionsOfStdlibhUsed.ql

c/misra/test/rules/RULE-1-5/MissingStaticSpecifierObjectRedeclarationC.expected

@@ -0,0 +1 @@
+| test.c:37:12:37:13 | declaration of g5 | The redeclaration of $@ with internal linkage misses the static specifier. | test.c:36:12:36:13 | definition of g5 | g5 |

c/misra/test/rules/RULE-1-5/MissingStaticSpecifierObjectRedeclarationC.qlref

@@ -0,0 +1 @@
+rules/RULE-8-8/MissingStaticSpecifierObjectRedeclarationC.ql

c/misra/test/rules/RULE-1-5/StandardLibraryInputoutputFunctionsUsed.expected

@@ -0,0 +1,3 @@
+| test.c:57:3:57:8 | call to ungetc | Call to banned function ungetc. |
+| test.c:60:3:60:7 | call to fread | Call to banned function fread. |
+| test.c:62:3:62:8 | call to ungetc | Call to banned function ungetc. |

c/misra/test/rules/RULE-1-5/StandardLibraryInputoutputFunctionsUsed.qlref

@@ -0,0 +1 @@
+rules/RULE-21-6/StandardLibraryInputoutputFunctionsUsed.ql

c/misra/test/rules/RULE-1-5/UseOfObsoleteMacroAtomicVarInit.expected

@@ -0,0 +1 @@
+| test.c:30:18:30:36 | ATOMIC_VAR_INIT(value) | Usage of macro ATOMIC_VAR_INIT() is considered obsolete for c version -std=c17 |

c/misra/test/rules/RULE-1-5/UseOfObsoleteMacroAtomicVarInit.qlref

@@ -0,0 +1 @@
+rules/RULE-1-5/UseOfObsoleteMacroAtomicVarInit.ql

c/misra/test/rules/RULE-1-5/options

@@ -0,0 +1 @@
+semmle-extractor-options:-std=c17 -I../../../../common/test/includes/standard-library

c/misra/test/rules/RULE-1-5/test.c

@@ -0,0 +1,63 @@
+// Compiled with -std=c17
+
+#include "stdatomic.h"
+#include "stdbool.h"
+#include "stdio.h"
+#include "stdlib.h"
+
+void f1(void) {
+  // malloc() is not obsolete, but banned by Rule 21.3
+  int *t = malloc(10); // COMPLIANT[False Negative]
+
+  // Obsolete usage of realloc.
+  realloc(t, 0); // NON-COMPLIANT
+
+  // Valid usage of realloc, but all use of realloc is banned by Rule 21.3
+  realloc(t, 20); // NON-COMPLIANT
+}
+
+extern const int g1; // COMPLIANT
+const extern int g2; // NON-COMPLIANT
+
+#define MY_TRUE 3  // COMPLIANT
+#define true 3     // NON-COMPLIANT
+#define false 3    // NON-COMPLIANT
+#define bool int * // NON-COMPLIANT
+#undef true        // NON-COMPLIANT
+#undef false       // NON-COMPLIANT
+#undef bool        // NON-COMPLIANT
+
+_Atomic int g3 = ATOMIC_VAR_INIT(18); // NON-COMPLIANT
+_Atomic int g4 = 18;                  // COMPLIANT
+
+// The following cases are already covered by other rules:
+
+// Rule 8.8:
+static int g5 = 3; // COMPLIANT
+extern int g5;     // NON-COMPLIANT
+
+// Rule 8.2:
+void f2();     // NON-COMPLIANT
+void f3(void); // COMPLIANT
+
+void f4(int p1) {}; // COMPLIANT
+int f5(x)           // NON_COMPLIANT
+int x;
+{
+  return 1;
+}
+
+// Rule 21.6 covers the below cases:
+void f6(void) {
+  // `gets` was removed from C11.
+  // gets(stdin); // NON_COMPLIANT
+
+  FILE *file = fopen("", 0);
+  // Obsolete usage of ungetc.
+  ungetc('c', file); // NON-COMPLIANT
+
+  char buf[10];
+  fread(buf, sizeof(buf), 10, file);
+  // This is not an obsolete usage of ungetc, but ungetc isn't allowed.
+  ungetc('c', file); // NON-COMPLIANT[FALSE NEGATIVE]
+}

cpp/common/src/codingstandards/cpp/exclusions/c/Language4.qll

@@ -0,0 +1,61 @@
+//** THIS FILE IS AUTOGENERATED, DO NOT MODIFY DIRECTLY.  **/
+import cpp
+import RuleMetadata
+import codingstandards.cpp.exclusions.RuleMetadata
+
+newtype Language4Query =
+  TUseOfObsoleteMacroAtomicVarInitQuery() or
+  TInvalidDefineOrUndefOfStdBoolMacroQuery() or
+  TCallToReallocWithSizeZeroQuery()
+
+predicate isLanguage4QueryMetadata(Query query, string queryId, string ruleId, string category) {
+  query =
+    // `Query` instance for the `useOfObsoleteMacroAtomicVarInit` query
+    Language4Package::useOfObsoleteMacroAtomicVarInitQuery() and
+  queryId =
+    // `@id` for the `useOfObsoleteMacroAtomicVarInit` query
+    "c/misra/use-of-obsolete-macro-atomic-var-init" and
+  ruleId = "RULE-1-5" and
+  category = "required"
+  or
+  query =
+    // `Query` instance for the `invalidDefineOrUndefOfStdBoolMacro` query
+    Language4Package::invalidDefineOrUndefOfStdBoolMacroQuery() and
+  queryId =
+    // `@id` for the `invalidDefineOrUndefOfStdBoolMacro` query
+    "c/misra/invalid-define-or-undef-of-std-bool-macro" and
+  ruleId = "RULE-1-5" and
+  category = "required"
+  or
+  query =
+    // `Query` instance for the `callToReallocWithSizeZero` query
+    Language4Package::callToReallocWithSizeZeroQuery() and
+  queryId =
+    // `@id` for the `callToReallocWithSizeZero` query
+    "c/misra/call-to-realloc-with-size-zero" and
+  ruleId = "RULE-1-5" and
+  category = "required"
+}
+
+module Language4Package {
+  Query useOfObsoleteMacroAtomicVarInitQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `useOfObsoleteMacroAtomicVarInit` query
+      TQueryC(TLanguage4PackageQuery(TUseOfObsoleteMacroAtomicVarInitQuery()))
+  }
+
+  Query invalidDefineOrUndefOfStdBoolMacroQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `invalidDefineOrUndefOfStdBoolMacro` query
+      TQueryC(TLanguage4PackageQuery(TInvalidDefineOrUndefOfStdBoolMacroQuery()))
+  }
+
+  Query callToReallocWithSizeZeroQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `callToReallocWithSizeZero` query
+      TQueryC(TLanguage4PackageQuery(TCallToReallocWithSizeZeroQuery()))
+  }
+}

cpp/common/src/codingstandards/cpp/exclusions/c/RuleMetadata.qll

@@ -39,6 +39,7 @@ import InvalidMemory2
 import Language1
 import Language2
 import Language3
+import Language4
 import Memory1
 import Memory2
 import Memory3
@@ -112,6 +113,7 @@ newtype TCQuery =
   TLanguage1PackageQuery(Language1Query q) or
   TLanguage2PackageQuery(Language2Query q) or
   TLanguage3PackageQuery(Language3Query q) or
+  TLanguage4PackageQuery(Language4Query q) or
   TMemory1PackageQuery(Memory1Query q) or
   TMemory2PackageQuery(Memory2Query q) or
   TMemory3PackageQuery(Memory3Query q) or
@@ -185,6 +187,7 @@ predicate isQueryMetadata(Query query, string queryId, string ruleId, string cat
   isLanguage1QueryMetadata(query, queryId, ruleId, category) or
   isLanguage2QueryMetadata(query, queryId, ruleId, category) or
   isLanguage3QueryMetadata(query, queryId, ruleId, category) or
+  isLanguage4QueryMetadata(query, queryId, ruleId, category) or
   isMemory1QueryMetadata(query, queryId, ruleId, category) or
   isMemory2QueryMetadata(query, queryId, ruleId, category) or
   isMemory3QueryMetadata(query, queryId, ruleId, category) or

rule_packages/c/Language4.json

@@ -0,0 +1,47 @@
+{
+  "MISRA-C-2012": {
+    "RULE-1-5": {
+      "properties": {
+        "obligation": "required"
+      },
+      "queries": [
+        {
+          "description": "The macro ATOMIC_VAR_INIT is has been declared an obsolescent language feature since C18.",
+          "kind": "problem",
+          "name": "Disallowed usage of obsolete macro ATOMIC_VAR_INIT compiled as C18",
+          "precision": "very-high",
+          "severity": "recommendation",
+          "short_name": "UseOfObsoleteMacroAtomicVarInit",
+          "tags": [
+            "maintainability",
+            "readability"
+          ]
+        },
+        {
+          "description": "Directives that undefine and/or redefine the standard boolean macros has been declared an obsolescent language feature since C99.",
+          "kind": "problem",
+          "name": "Programs may not undefine or redefine the macros bool, true, or false",
+          "precision": "very-high",
+          "severity": "warning",
+          "short_name": "InvalidDefineOrUndefOfStdBoolMacro",
+          "tags": [
+            "maintainability",
+            "readability"
+          ]
+        },
+        {
+          "description": "Invoking realloc with a size argument set to zero is implementation-defined behavior and declared as an obsolete feature in C18.",
+          "kind": "problem",
+          "name": "Disallowed size argument value equal to zero in call to realloc",
+          "precision": "very-high",
+          "severity": "error",
+          "short_name": "CallToReallocWithSizeZero",
+          "tags": [
+            "correctness"
+          ]
+        }
+      ],
+      "title": "Obsolencent language features shall not be used"
+    }
+  }
+}