To use PSRAM

[Nezaemmy]

@lbernstone Hi, I want to use PSRAM on my Esp32s3 with 8M PSRAM, I use the board in the arduino-matter and homekit project code.
It is my first time to start using PSRAM, I enabled PSRAM in Arduino IDE tools. I want to ask you the code I can add in my code I created so that I can use PSRAM with internal memory.
Let us take this matter example, Help me so that this code also use PSRAM

// Matter Manager
#include <Matter.h>
#include <WiFi.h>
#include <Preferences.h>

// WiFi is manually set and started
const char *ssid = "your-ssid";          // Change this to your WiFi SSID
const char *password = "your-password";  // Change this to your WiFi password

// List of Matter Endpoints for this Node
// On/Off Light Endpoint
MatterOnOffLight OnOffLight;

// it will keep last OnOff state stored, using Preferences
Preferences matterPref;
const char *onOffPrefKey = "OnOff";

// set your board LED pin here
#ifdef LED_BUILTIN
const uint8_t ledPin = LED_BUILTIN;
#else
const uint8_t ledPin = 2;  // Set your pin here if your board has not defined LED_BUILTIN
#warning "Do not forget to set the LED pin"
#endif

// set your board USER BUTTON pin here
const uint8_t buttonPin = BOOT_PIN;  // Set your pin here. Using BOOT Button.

// Button control
uint32_t button_time_stamp = 0;                // debouncing control
bool button_state = false;                     // false = released | true = pressed
const uint32_t debouceTime = 250;              // button debouncing time (ms)
const uint32_t decommissioningTimeout = 5000;  // keep the button pressed for 5s, or longer, to decommission

// Matter Protocol Endpoint Callback
bool setLightOnOff(bool state) {
  Serial.printf("User Callback :: New Light State = %s\r\n", state ? "ON" : "OFF");
  if (state) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }
  // store last OnOff state for when the Light is restarted / power goes off
  matterPref.putBool(onOffPrefKey, state);
  // This callback must return the success state to Matter core
  return true;
}

void setup() {
  // Initialize the USER BUTTON (Boot button) GPIO that will act as a toggle switch
  pinMode(buttonPin, INPUT_PULLUP);
  // Initialize the LED (light) GPIO and Matter End Point
  pinMode(ledPin, OUTPUT);

  Serial.begin(115200);

  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  // Manually connect to WiFi
  WiFi.begin(ssid, password);
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\r\nWiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  delay(500);

  // Initialize Matter EndPoint
  matterPref.begin("MatterPrefs", false);
  bool lastOnOffState = matterPref.getBool(onOffPrefKey, true);
  OnOffLight.begin(lastOnOffState);
  OnOffLight.onChange(setLightOnOff);

  // Matter beginning - Last step, after all EndPoints are initialized
  Matter.begin();
  // This may be a restart of a already commissioned Matter accessory
  if (Matter.isDeviceCommissioned()) {
    Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use.");
    Serial.printf("Initial state: %s\r\n", OnOffLight.getOnOff() ? "ON" : "OFF");
    OnOffLight.updateAccessory();  // configure the Light based on initial state
  }
}

void loop() {
  // Check Matter Light Commissioning state, which may change during execution of loop()
  if (!Matter.isDeviceCommissioned()) {
    Serial.println("");
    Serial.println("Matter Node is not commissioned yet.");
    Serial.println("Initiate the device discovery in your Matter environment.");
    Serial.println("Commission it to your Matter hub with the manual pairing code or QR code");
    Serial.printf("Manual pairing code: %s\r\n", Matter.getManualPairingCode().c_str());
    Serial.printf("QR code URL: %s\r\n", Matter.getOnboardingQRCodeUrl().c_str());
    // waits for Matter Light Commissioning.
    uint32_t timeCount = 0;
    while (!Matter.isDeviceCommissioned()) {
      delay(100);
      if ((timeCount++ % 50) == 0) {  // 50*100ms = 5 sec
        Serial.println("Matter Node not commissioned yet. Waiting for commissioning.");
      }
    }
    Serial.printf("Initial state: %s\r\n", OnOffLight.getOnOff() ? "ON" : "OFF");
    OnOffLight.updateAccessory();  // configure the Light based on initial state
    Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use.");
  }

  // A button is also used to control the light
  // Check if the button has been pressed
  if (digitalRead(buttonPin) == LOW && !button_state) {
    // deals with button debouncing
    button_time_stamp = millis();  // record the time while the button is pressed.
    button_state = true;           // pressed.
  }

  // Onboard User Button is used as a Light toggle switch or to decommission it
  uint32_t time_diff = millis() - button_time_stamp;
  if (button_state && time_diff > debouceTime && digitalRead(buttonPin) == HIGH) {
    button_state = false;  // released
    // Toggle button is released - toggle the light
    Serial.println("User button released. Toggling Light!");
    OnOffLight.toggle();  // Matter Controller also can see the change
  }

  // Onboard User Button is kept pressed for longer than 5 seconds in order to decommission matter node
  if (button_state && time_diff > decommissioningTimeout) {
    Serial.println("Decommissioning the Light Matter Accessory. It shall be commissioned again.");
    OnOffLight.setOnOff(false);  // turn the light off
    Matter.decommission();
    button_time_stamp = millis();  // avoid running decommissining again, reboot takes a second or so
  }
}

[me-no-dev]

if you have enabled it in the menu, then you already have it added to the heap. You can use malloc() and such to allocate the memory you need. If you want to force the use of PSRAM, then you can use ps_malloc() instead.

[Nezaemmy]

@me-no-dev thank you for guidance.
For sure I don't know how to use malloc() or ps_malloc() in the code. I tried on internet but I didn't find a good guidance.
Is malloc() or ps_malloc() be before void setup () or after?
Help me to add the lines of codes on my code above so that I can know exactly where and how to use.
Please help me

[SuGlider]

@Nezaemmy - this link may help you:
https://forum.arduino.cc/t/esp32-how-to-use-psram-ps-malloc/1055481

[Nezaemmy]

@Nezaemmy - this link may help you: https://forum.arduino.cc/t/esp32-how-to-use-psram-ps-malloc/1055481

Thank you @SuGlider.
my question; Can I use PSRAM to allocate memory buffers if I use many endpoints?
I took an example of MatterOnOffLight.ino I wanted to know how I can add PSRAM code so that the buffers can be allocated automatically in PSRAM when DSRAM is not enough.

[SuGlider]

my question; Can I use PSRAM to allocate memory buffers if I use many endpoints?

Yes, there is no problem. IDF will treat PSRAM the same way it does with SRAM.
Any malloc(SIZE) or buffer declaration (such as uint8_t bufer[SIZE]) that has SIZE higher than 4096 bytes will be allocated in PSRAM, always when PSRAM is enabled in the configuration.

No need to do any special operation. Just enable PSRAM in the IDE Menu.

[SuGlider]

PSRAM allocation is transparent for the user and application.

It is possible to check Memory size and availability, which can be printed using printAfterSetupInfo() which will issue a report to the Serial port.
The sketch shall #include <chip-debug-report.h> in order to use it.

You can also check more functions and its use in the ESP32 Arduino Source code at cores/esp32