Support REPL flavors and Lumo

This patch adds the `inf-clojure-repl-flavor` defcustom in order to
support different kind of configurations based on the selected flavor.
The default flavor is `'clojure`, and the other supported one is
`'lumo`.  It also adds other vars to further customize hostname, port
and classpath used in the Lumo flavor.

Author: arichiardi

inf-clojure.el

@@ -44,6 +44,7 @@
 (require 'thingatpt)
 (require 'ansi-color)
 (require 'cl-lib)
+(require 'subr-x)
 
 
 (defgroup inf-clojure nil
@@ -148,6 +149,7 @@ The following commands are available:
 
 \\{inf-clojure-minor-mode-map}"
   :lighter "" :keymap inf-clojure-minor-mode-map
+  (setq comint-input-sender 'inf-clojure--send-string)
   (inf-clojure-eldoc-setup)
   (make-local-variable 'completion-at-point-functions)
   (add-to-list 'completion-at-point-functions
@@ -183,6 +185,30 @@ often connecting to a remote REPL process."
   :type '(choice (string)
                  (cons string integer)))
 
+(defvar-local inf-clojure-repl-flavor nil
+  "Symbol to define your REPL flavor.
+Its root binding is nil and it can be further customized using
+either `setq-local` or an entry in `.dir-locals.el`." )
+
+(defun inf-clojure--probe-flavor (proc)
+  "Identifies the current REPL flavor for PROC."
+  (cond
+   ((inf-clojure--lumo-p proc) 'lumo)
+   (t 'clojure)))
+
+(defun inf-clojure--set-flavor (proc)
+  "Set the flavor if has not already been set."
+  (when (not inf-clojure-repl-flavor)
+    (setq inf-clojure-repl-flavor (inf-clojure--probe-flavor proc))))
+
+(defun inf-clojure--send-string (proc string)
+  "A custom `comint-input-sender` / `comint-send-string`.
+Perform the required side effects on every send for PROC and
+STRING (for example set the buffer local REPL flavor).  It should
+be used instead of `comint-send-string`."
+  (inf-clojure--set-flavor proc)
+  (comint-simple-send proc string))
+
 (defcustom inf-clojure-load-command "(clojure.core/load-file \"%s\")\n"
   "Format-string for building a Clojure expression to load a file.
 This format string should use `%s' to substitute a file name
@@ -296,6 +322,7 @@ If `comint-use-prompt-regexp' is nil (the default), \\[comint-insert-input] on o
 Paragraphs are separated only by blank lines.  Semicolons start comments.
 If you accidentally suspend your process, use \\[comint-continue-subjob]
 to continue it."
+  (setq comint-input-sender 'inf-clojure--send-string)
   (setq comint-prompt-regexp inf-clojure-comint-prompt-regexp)
   (setq mode-line-process '(":%s"))
   (clojure-mode-variables)
@@ -408,12 +435,12 @@ Prefix argument AND-GO means switch to the Clojure buffer afterwards."
   (let ((str (replace-regexp-in-string
               "[\n]*\\'" "\n"
               (buffer-substring-no-properties start end))))
-    (comint-send-string (inf-clojure-proc) str))
+    (inf-clojure--send-string (inf-clojure-proc) str))
   (if and-go (inf-clojure-switch-to-repl t)))
 
 (defun inf-clojure-eval-string (code)
   "Send the string CODE to the inferior Clojure process to be executed."
-  (comint-send-string (inf-clojure-proc) (concat code "\n")))
+  (inf-clojure--send-string (inf-clojure-proc) (concat code "\n")))
 
 (defun inf-clojure-eval-defun (&optional and-go)
   "Send the current defun to the inferior Clojure process.
@@ -504,8 +531,8 @@ The prefix argument SWITCH-TO-REPL controls whether to switch to REPL after the
     (comint-check-source file-name) ; Check to see if buffer needs saved.
     (setq inf-clojure-prev-l/c-dir/file (cons (file-name-directory    file-name)
                                               (file-name-nondirectory file-name)))
-    (comint-send-string (inf-clojure-proc)
-                        (format inf-clojure-load-command file-name))
+    (inf-clojure--send-string (inf-clojure-proc)
+                              (format inf-clojure-load-command file-name))
     (when switch-to-repl
       (inf-clojure-switch-to-repl t))))
 
@@ -683,7 +710,7 @@ See variable `inf-clojure-macroexpand-command'.
 With a prefix arg MACRO-1 uses `inf-clojure-macroexpand-1-command'."
   (interactive "P")
   (let ((last-sexp (buffer-substring-no-properties (save-excursion (backward-sexp) (point)) (point))))
-    (comint-send-string
+    (inf-clojure--send-string
      (inf-clojure-proc)
      (format (if macro-1
                  inf-clojure-macroexpand-1-command
@@ -876,6 +903,39 @@ to suppress the usage of the target buffer discovery logic."
     (inf-clojure (inf-clojure-cmd (inf-clojure-project-type)))
     (rename-buffer target-buffer-name)))
 
-(provide 'inf-clojure)
+(defun inf-clojure--response-match-p (form match-p proc)
+  "Return MATCH-P on the result of sending FORM to PROC.
+Note that this function will add a \n to the end of the string
+for evaluation, therefore FORM should not include it."
+  (let* ((kept "")
+         (is-matching nil)
+         (prev-filter (process-filter proc)))
+    (set-process-filter proc (lambda (_ string) (setq kept (concat kept string))))
+    (unwind-protect
+        ;; use the real comind-send-string in order to avoid stack overflows
+        (comint-send-string proc (concat form "\n"))
+      ;; yey, loads of procedural code again
+      (while (and (not is-matching)
+                  (not (string-match inf-clojure-prompt kept))
+                  (accept-process-output proc 2))
+        (setq is-matching (funcall match-p kept)))
+      (set-process-filter proc prev-filter))
+    is-matching))
+
+;;;; Lumo
+;;;; ====
+
+(defcustom inf-clojure--lumo-repl-form
+  "(js/global.hasOwnProperty \"$$LUMO_GLOBALS\")"
+  "Form to invoke in order to verify that we launched a Lumo REPL."
+  :type 'string)
 
+(defalias 'inf-clojure--lumo-p
+  (apply-partially 'inf-clojure--response-match-p
+                   inf-clojure--lumo-repl-form
+                   (lambda (string)
+                     (string-match-p (concat inf-clojure--lumo-repl-form "\\Ca*true\\Ca*") string)))
+  "Ascertain that PROC is a Lumo REPL.")
+
+(provide 'inf-clojure)
 ;;; inf-clojure.el ends here