Mark put-clojure-indent safe for use in .dir-locals.el, etc.

Add a put-clojure-indent form validator and attach it as a
safe-local-eval-function property so that safe invocations won't
trigger open-file prompts when used in local variables, or when added
to .dir-locals.el like this:

  ((clojure-mode
    (eval . (put-clojure-indent 'defrecord '(2 :form :form (1))))))

For now, only support specs specified as lists, not vectors.

Author: rlbdv

clojure-mode.el

@@ -1554,6 +1554,53 @@ This function also returns nil meaning don't specify the indentation."
   "Instruct `clojure-indent-function' to indent the body of SYM by INDENT."
   (put sym 'clojure-indent-function indent))
 
+(defun clojure--maybe-quoted-symbol-p (x)
+  "Check that X is either a symbol or a quoted symbol like :foo or 'foo."
+  (or (symbolp x)
+      (and (listp x)
+           (= 2 (length x))
+           (eq 'quote (car x))
+           (symbolp (cadr x)))))
+
+(defun clojure--valid-unquoted-indent-spec-p (spec)
+  "Check that the indentation SPEC is valid.
+Validate it with respect to
+https://docs.cider.mx/cider/indent_spec.html e.g. (2 :form
+:form (1)))."
+  (or (integerp spec)
+      (memq spec '(:form :defn))
+      (and (listp spec)
+           (not (null spec))
+           (or (integerp (car spec))
+               (memq (car spec) '(:form :defn)))
+           (seq-every-p 'clojure--valid-unquoted-indent-spec-p (cdr spec)))))
+
+(defun clojure--valid-indent-spec-p (spec)
+  "Check that the indentation SPEC (quoted if a list) is valid.
+Validate it with respect to
+https://docs.cider.mx/cider/indent_spec.html e.g. (2 :form
+:form (1)))."
+  (or (integerp spec)
+      (and (keywordp spec) (memq spec '(:form :defn)))
+      (and (listp spec)
+           (= 2 (length spec))
+           (eq 'quote (car spec))
+           (clojure--valid-unquoted-indent-spec-p (cadr spec)))))
+
+(defun clojure--valid-put-clojure-indent-call-p (exp)
+  "Check that EXP is a valid `put-clojure-indent' expression.
+For example: (put-clojure-indent 'defrecord '(2 :form :form (1))."
+  (unless (and (listp exp)
+               (= 3 (length exp))
+               (eq 'put-clojure-indent (nth 0 exp))
+               (clojure--maybe-quoted-symbol-p (nth 1 exp))
+               (clojure--valid-indent-spec-p (nth 2 exp)))
+    (error "Unrecognized put-clojure-indent call: %s" exp))
+  t)
+
+(put 'put-clojure-indent 'safe-local-eval-function
+     'clojure--valid-put-clojure-indent-call-p)
+
 (defmacro define-clojure-indent (&rest kvs)
   "Call `put-clojure-indent' on a series, KVS."
   `(progn

test/clojure-mode-safe-eval-test.el

@@ -0,0 +1,74 @@
+;;; clojure-mode-safe-eval-test.el --- Clojure Mode: safe eval test suite  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2014-2021 Bozhidar Batsov <bozhidar@batsov.com>
+;; Copyright (C) 2021 Rob Browning <rlb@defaultvalue.org>
+
+;; This file is not part of GNU Emacs.
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; The safe eval test suite of Clojure Mode
+
+;;; Code:
+(require 'clojure-mode)
+(require 'buttercup)
+
+(describe "put-clojure-indent safe-local-eval-function property"
+  (it "should be set to clojure--valid-put-clojure-indent-call-p"
+      (expect (get 'put-clojure-indent 'safe-local-eval-function)
+              :to-be 'clojure--valid-put-clojure-indent-call-p)))
+
+(describe "clojure--valid-put-clojure-indent-call-p"
+  (it "should approve valid forms"
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo 1)))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo :defn)))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo :form)))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(1))))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(:defn))))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(:form))))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(1 1))))
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(2 :form :form (1))))))
+  (it "should reject invalid forms"
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 1 1))
+              :to-throw 'error)
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo :foo))
+              :to-throw 'error)
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo (:defn)))
+              :to-throw 'error)
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(:foo)))
+              :to-throw 'error)
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(1 :foo)))
+              :to-throw 'error)
+      (expect (clojure--valid-put-clojure-indent-call-p
+               '(put-clojure-indent 'foo '(1 "foo")))
+              :to-throw 'error)))
+
+(provide 'clojure-mode-safe-eval-test)
+
+;;; clojure-mode-safe-eval-test.el ends here